Rules for integrands of the form(((d+e x))^m)(((a+b x+c (x^2)))^p)

x:  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  (b^2)-4 a c==0, then a+b x+c (x^2)==(1/c) ((((b/2)+c x))^2)

Rule 1.2.1.2.2.1: If  (b^2)-4 a c==0 ∧ p∈ℤ, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  (1/(c^p))∫(((d+e x))^m) ((((b/2)+c x))^(2 p))dx

Program code:

(* Int[(d_.+e_.*x_)^m_.*(a_+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  1/c^p*Int[(d+e*x)^m*(b/2+c*x)^(2*p),x] /;
FreeQ[{a,b,c,d,e,m},x] && EqQ[b^2-4*a*c,0] && IntegerQ[p] *)

0:  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ (p∈ℤ ∨ b==0 ∧ a>0 ∧ d>0 ∧ m+p∈ℤ)

Derivation: Algebraic simplification

Basis: If  c (d^2)-b d e+a (e^2)==0, then a+b x+c (x^2)==(d+e x) ((a/d)+((c x)/e))

Basis: If  c (d^2)+a (e^2)==0 ∧ a>0 ∧ d>0, then (((a+c (x^2)))^p)==(((a-((a (e^2) (x^2))/(d^2))))^p)==(((d+e x))^p) ((((a/d)+((c x)/e)))^p)

Rule 1.2.1.2.3.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ (p∈ℤ ∨ b==0 ∧ a>0 ∧ d>0 ∧ m+p∈ℤ), then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  ∫(((d+e x))^(m+p)) ((((a/d)+((c x)/e)))^p)dx

Program code:

Int[(d_+e_.*x_)^m_.*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  Int[(d+e*x)^(m+p)*(a/d+c/e*x)^p,x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[p]

Int[(d_+e_.*x_)^m_.*(a_+c_.*x_^2)^p_.,x_Symbol] :=
  Int[(d+e*x)^(m+p)*(a/d+c/e*x)^p,x] /;
FreeQ[{a,c,d,e,m,p},x] && EqQ[c*d^2+a*e^2,0] && (IntegerQ[p] || GtQ[a,0] && GtQ[d,0] && IntegerQ[m+p])

1.  ∫(d+e x) (((a+b x+c (x^2)))^p)dx

1.  ∫(d+e x) (((a+b x+c (x^2)))^p)dx  when 2 c d-b e==0

1:  ∫((d+e x)/(a+b x+c (x^2)))dx  when 2 c d-b e==0

Derivation: Integration by substitution

Basis: If  2 c d-b e==0, then (d+e x) F[a+b x+c (x^2)]==(d/b) Subst[F[x],x,a+b x+c (x^2)] (∂_x)(a+b x+c (x^2))

Rule 1.2.1.2.1.1.1: If  2 c d-b e==0, then

∫((d+e x)/(a+b x+c (x^2)))dx  ⟶  (d/b) Subst[∫(1/x) dx,x,a+b x+c (x^2)]  ⟶  ((d Log[a+b x+c (x^2)])/b)

Program code:

Int[(d_+e_.*x_)/(a_.+b_.*x_+c_.*x_^2),x_Symbol] :=
  d*Log[RemoveContent[a+b*x+c*x^2,x]]/b /;
FreeQ[{a,b,c,d,e},x] && EqQ[2*c*d-b*e,0]

2:  ∫(d+e x) (((a+b x+c (x^2)))^p)dx  when 2 c d-b e==0 ∧ p≠-1

Derivation: Integration by substitution

Basis: If  2 c d-b e==0, then (d+e x) F[a+b x+c (x^2)]==(d/b) Subst[F[x],x,a+b x+c (x^2)] (∂_x)(a+b x+c (x^2))

Rule 1.2.1.2.1.1.2: If  2 c d-b e==0 ∧ p≠-1, then

∫(d+e x) (((a+b x+c (x^2)))^p)dx  ⟶  (d/b) Subst[∫(x^p) dx,x,a+b x+c (x^2)]  ⟶  ((d (((a+b x+c (x^2)))^(p+1)))/(b (p+1)))

Program code:

Int[(d_+e_.*x_)*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  d*(a+b*x+c*x^2)^(p+1)/(b*(p+1)) /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[2*c*d-b*e,0] && NeQ[p,-1]

2.  ∫(d+e x) (((a+b x+c (x^2)))^p)dx  when 2 c d-b e≠0

1.  ∫(d+e x) (((a+b x+c (x^2)))^p)dx  when 2 c d-b e≠0 ∧ p∈ℤ ∧(p>0 ∨ a==0)

1:  ∫(d+e x) (((a+b x+c (x^2)))^p)dx  when 2 c d-b e≠0 ∧ p∈(SuperPlus[ℤ])∧ c (d^2)-b d e+a (e^2)==0

Derivation: Algebraic simplification

Basis: If  c (d^2)-b d e+a (e^2)==0, then a+b x+c (x^2)==(d+e x) ((a/d)+((c x)/e))

Rule 1.2.1.2.1.2.1.1: If  2 c d-b e≠0 ∧ p∈(SuperPlus[ℤ])∧ c (d^2)-b d e+a (e^2)==0, then

∫(d+e x) (((a+b x+c (x^2)))^p)dx  ⟶  ∫(((d+e x))^(p+1)) ((((a/d)+((c x)/e)))^p)dx

Program code:

Int[(d_+e_.*x_)*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  Int[(d+e*x)^(p+1)*(a/d+c/e*x)^p,x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[2*c*d-b*e,0] && IGtQ[p,0] && EqQ[c*d^2-b*d*e+a*e^2,0]

2:  ∫(d+e x) (((a+b x+c (x^2)))^p)dx  when 2 c d-b e≠0 ∧ p∈ℤ ∧(p>0 ∨ a==0)

Derivation: Algebraic expansion

Rule 1.2.1.2.1.2.1.2: If  2 c d-b e≠0 ∧ p∈ℤ ∧(p>0 ∨ a==0), then

∫(d+e x) (((a+b x+c (x^2)))^p)dx  ⟶  ∫ExpandIntegrand[(d+e x) (((a+b x+c (x^2)))^p),x]dx

Program code:

Int[(d_.+e_.*x_)*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)*(a+b*x+c*x^2)^p,x],x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[2*c*d-b*e,0] && IntegerQ[p] && (GtQ[p,0] || EqQ[a,0])

2.  ∫((d+e x)/(a+b x+c (x^2)))dx  when 2 c d-b e≠0 ∧ (b^2)-4 a c≠0

1:  ∫((d+e x)/(a+b x+c (x^2)))dx  when 2 c d-b e≠0 ∧ (b^2)-4 a c≠0 ∧ NiceSqrtQ[(b^2)-4 a c]

Reference: G&R 2.161.1a & G&R 2.161.3

Derivation: Algebraic expansion

Basis: Let q=(Sqrt[(b^2)-4 a c]), then ((d+e x)/(a+b x+c (x^2)))==((c d-e ((b/2)-(q/2)))/(q ((b/2)-(q/2)+c x)))-((c d-e ((b/2)+(q/2)))/(q ((b/2)+(q/2)+c x)))

Rule 1.2.1.2.1.2.2.1: If  2 c d-b e≠0 ∧ (b^2)-4 a c≠0 ∧ NiceSqrtQ[(b^2)-4 a c], let q->(Sqrt[(b^2)-4 a c]), then

∫((d+e x)/(a+b x+c (x^2)))dx  ⟶  ((c d-e ((b/2)-(q/2)))/q)∫(1/((b/2)-(q/2)+c x))dx-((c d-e ((b/2)+(q/2)))/q)∫(1/((b/2)+(q/2)+c x))dx

Program code:

Int[(d_.+e_.*x_)/(a_+b_.*x_+c_.*x_^2),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  (c*d-e*(b/2-q/2))/q*Int[1/(b/2-q/2+c*x),x] - (c*d-e*(b/2+q/2))/q*Int[1/(b/2+q/2+c*x),x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[2*c*d-b*e,0] && NeQ[b^2-4*a*c,0] && NiceSqrtQ[b^2-4*a*c]

Int[(d_+e_.*x_)/(a_+c_.*x_^2),x_Symbol] :=
  With[{q=Rt[-a*c,2]},
  (e/2+c*d/(2*q))*Int[1/(-q+c*x),x] + (e/2-c*d/(2*q))*Int[1/(q+c*x),x]] /;
FreeQ[{a,c,d,e},x] && NiceSqrtQ[-a*c]

2:  ∫((d+e x)/(a+b x+c (x^2)))dx  when 2 c d-b e≠0 ∧ (b^2)-4 a c≠0 ∧ ¬NiceSqrtQ[(b^2)-4 a c]

Reference: A&S 3.3.19

Derivation: Algebraic expansion

Basis: ((d+e x)/(a+b x+c (x^2)))==(d-((b e)/(2 c)))(1/(a+b x+c (x^2)))+((e (b+2 c x))/(2 c (a+b x+c (x^2))))

Note: ((b+2 c x)/(a+b x+c (x^2)))is easily integrated using the rules for when 2 c d-b e==0.

Rule 1.2.1.2.1.2.2.2: If  2 c d-b e≠0 ∧ (b^2)-4 a c≠0 ∧ ¬NiceSqrtQ[(b^2)-4 a c], then

∫((d+e x)/(a+b x+c (x^2)))dx  ⟶  ((2 c d-b e)/(2 c)) ∫(1/(a+b x+c (x^2)))dx+(e/(2 c))∫((b+2 c x)/(a+b x+c (x^2)))dx

Program code:

Int[(d_.+e_.*x_)/(a_+b_.*x_+c_.*x_^2),x_Symbol] :=
(* (d-b*e/(2*c))*Int[1/(a+b*x+c*x^2),x] + *)
  (2*c*d-b*e)/(2*c)*Int[1/(a+b*x+c*x^2),x] + e/(2*c)*Int[(b+2*c*x)/(a+b*x+c*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[2*c*d-b*e,0] && NeQ[b^2-4*a*c,0] && Not[NiceSqrtQ[b^2-4*a*c]]

Int[(d_+e_.*x_)/(a_+c_.*x_^2),x_Symbol] :=
  d*Int[1/(a+c*x^2),x] + e*Int[x/(a+c*x^2),x] /;
FreeQ[{a,c,d,e},x] && Not[NiceSqrtQ[-a*c]]

3.  ∫(d+e x) (((a+b x+c (x^2)))^p)dx  when 2 c d-b e≠0 ∧ (b^2)-4 a c≠0 ∧ p<-1

1:  ∫((d+e x)/(((a+b x+c (x^2)))^(3/2)))dx  when  2 c d-b e≠0 ∧ (b^2)-4 a c≠0

Derivation: Quadratic recurrence 2a

Rule 1.2.1.2.1.2.3.1: If  2 c d-b e≠0 ∧ (b^2)-4 a c≠0, then

∫((d+e x)/(((a+b x+c (x^2)))^(3/2)))dx  ⟶  -((2 (b d-2 a e+(2 c d-b e) x))/(((b^2)-4 a c) (Sqrt[a+b x+c (x^2)])))

Program code:

Int[(d_.+e_.*x_)/(a_.+b_.*x_+c_.*x_^2)^(3/2),x_Symbol] :=
  -2*(b*d-2*a*e+(2*c*d-b*e)*x)/((b^2-4*a*c)*Sqrt[a+b*x+c*x^2]) /;
FreeQ[{a,b,c,d,e},x] && NeQ[2*c*d-b*e,0] && NeQ[b^2-4*a*c,0]

Int[(d_+e_.*x_)/(a_+c_.*x_^2)^(3/2),x_Symbol] :=
  (-a*e+c*d*x)/(a*c*Sqrt[a+c*x^2]) /;
FreeQ[{a,c,d,e},x]

2:  ∫(d+e x) (((a+b x+c (x^2)))^p)dx  when  2 c d-b e≠0 ∧ (b^2)-4 a c≠0 ∧ p<-1 ∧ p≠-(3/2)

Derivation: Quadratic recurrence 2a

Rule 1.2.1.2.1.2.3.2: If  2 c d-b e≠0 ∧ (b^2)-4 a c≠0 ∧ p<-1 ∧ p≠-(3/2), then

∫(d+e x)(((a+b x+c (x^2)))^p)dx  ⟶  
(( (b d-2 a e+(2 c d-b e) x)(((a+b x+c (x^2)))^(p+1)))/((p+1) ((b^2)-4 a c)))-(((2 p+3) (2 c d-b e))/((p+1) ((b^2)-4 a c) ))∫(((a+b x+c (x^2)))^(p+1))dx

Program code:

Int[(d_.+e_.*x_)*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (b*d-2*a*e+(2*c*d-b*e)*x)/((p+1)*(b^2-4*a*c))*(a+b*x+c*x^2)^(p+1) - 
  (2*p+3)*(2*c*d-b*e)/((p+1)*(b^2-4*a*c))*Int[(a+b*x+c*x^2)^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[2*c*d-b*e,0] && NeQ[b^2-4*a*c,0] && LtQ[p,-1] && NeQ[p,-3/2]

Int[(d_+e_.*x_)*(a_+c_.*x_^2)^p_,x_Symbol] :=
  (a*e-c*d*x)/(2*a*c*(p+1))*(a+c*x^2)^(p+1) + 
  d*(2*p+3)/(2*a*(p+1))*Int[(a+c*x^2)^(p+1),x] /;
FreeQ[{a,c,d,e},x] && LtQ[p,-1] && NeQ[p,-3/2]

4:  ∫(d+e x) (((a+b x+c (x^2)))^p)dx  when 2 c d-b e≠0 ∧ p≠-1

Reference: G&R 2.181.1, CRC 119

Derivation: Special quadratic recurrence 3a

Rule 1.2.1.2.1.2.4: If  2 c d-b e≠0 ∧ p≠-1, then

∫(d+e x) (((a+b x+c (x^2)))^p)dx  ⟶  ((e (((a+b x+c (x^2)))^(p+1)))/(2 c (p+1)))+((2 c d-b e)/(2 c))∫(((a+b x+c (x^2)))^p)dx

Program code:

Int[(d_.+e_.*x_)*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  e*(a+b*x+c*x^2)^(p+1)/(2*c*(p+1)) + (2*c*d-b*e)/(2*c)*Int[(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[2*c*d-b*e,0] && NeQ[p,-1]

Int[(d_+e_.*x_)*(a_+c_.*x_^2)^p_.,x_Symbol] :=
  e*(a+c*x^2)^(p+1)/(2*c*(p+1)) + d*Int[(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e,p},x] && NeQ[p,-1]

2.  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ

1.  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ ∧ 2 c d-b e==0

1.  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ ∧ 2 c d-b e==0 ∧ m∈ℤ

1:  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ ∧ 2 c d-b e==0 ∧ (m/2)∈ℤ

Derivation: Algebraic simplification

Basis: If  (b^2)-4 a c==0 ∧ 2 c d-b e==0 ∧ (m/2)∈ℤ, then (((d+e x))^m) (((a+b x+c (x^2)))^p)==((e^m)/(c^(m/2))) (((a+b x+c (x^2)))^(p+(m/2)))

Rule 1.2.1.2.2.2.1.1.1: If  (b^2)-4 a c==0 ∧ p∉ℤ ∧ 2 c d-b e==0 ∧ (m/2)∈ℤ, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  ((e^m)/(c^(m/2))) ∫(((a+b x+c (x^2)))^(p+(m/2)))dx

Program code:

Int[(d_+e_.*x_)^m_*(a_+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  e^m/c^(m/2)*Int[(a+b*x+c*x^2)^(p+m/2),x] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]] && EqQ[2*c*d-b*e,0] && IntegerQ[m/2]

2:  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ ∧ 2 c d-b e==0 ∧ ((m-1)/2)∈ℤ ∧ m≠1

Derivation: Algebraic simplification

Basis: If  (b^2)-4 a c==0 ∧ 2 c d-b e==0 ∧ ((m-1)/2)∈ℤ, then (((d+e x))^m) (((a+b x+c (x^2)))^p)==((e^(m-1))/(c^((m-1)/2))) (d+e x) (((a+b x+c (x^2)))^(p+((m-1)/2)))

Rule 1.2.1.2.2.2.1.1.2: If  (b^2)-4 a c==0 ∧ p∉ℤ ∧ 2 c d-b e==0 ∧ ((m-1)/2)∈ℤ ∧ m≠1, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  ((e^(m-1))/(c^((m-1)/2))) ∫(d+e x) (((a+b x+c (x^2)))^(p+((m-1)/2)))dx

Program code:

Int[(d_+e_.*x_)^m_*(a_+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  e^(m-1)/c^((m-1)/2)*Int[(d+e*x)*(a+b*x+c*x^2)^(p+(m-1)/2),x] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]] && EqQ[2*c*d-b*e,0] && IntegerQ[(m-1)/2]

2:  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ ∧ 2 c d-b e==0 ∧ m∉ℤ

Derivation: Piecewise constant extraction

Basis: If  (b^2)-4 a c==0 ∧ 2 c d-b e==0, then (∂_x)((((a+b x+c (x^2)))^p)/(((d+e x))^(2 p)))==0

Rule 1.2.1.2.2.2.1.2: If  (b^2)-4 a c==0 ∧ p∉ℤ ∧ 2 c d-b e==0 ∧ m∉ℤ, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  ((((a+b x+c (x^2)))^p)/(((d+e x))^(2 p))) ∫(((d+e x))^(m+2 p))dx

Program code:

Int[(d_+e_.*x_)^m_*(a_+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (a+b*x+c*x^2)^p/(d+e*x)^(2*p)*Int[(d+e*x)^(m+2*p),x] /;
FreeQ[{a,b,c,d,e,m,p},x] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]] && EqQ[2*c*d-b*e,0] && Not[IntegerQ[m]]

2.  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ ∧ 2 c d-b e≠0

1:  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ ∧ 2 c d-b e≠0 ∧ m∈(SuperPlus[ℤ])∧ m-2 p+1==0

Derivation: Piecewise constant extraction and algebraic expansion

Basis: If  (b^2)-4 a c==0, then (∂_x)((((a+b x+c (x^2)))^p)/((((b/2)+c x))^(2 p)))==0

Rule 1.2.1.2.2.2.2.1: If  (b^2)-4 a c==0 ∧ p∉ℤ ∧ 2 c d-b e≠0 ∧ m∈(SuperPlus[ℤ])∧ m-2 p+1==0, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  ((((a+b x+c (x^2)))^(FracPart[p]))/((c^(IntPart[p])) ((((b/2)+c x))^(2 FracPart[p]))))∫ExpandLinearProduct[((((b/2)+c x))^(2 p)),(((d+e x))^m),(b/2),c,x]dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (a+b*x+c*x^2)^FracPart[p]/(c^IntPart[p]*(b/2+c*x)^(2*FracPart[p]))*
    Int[ExpandLinearProduct[(b/2+c*x)^(2*p),(d+e*x)^m,b/2,c,x],x] /;
FreeQ[{a,b,c,d,e,m,p},x] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]] && NeQ[2*c*d-b*e,0] && IGtQ[m,0] && EqQ[m-2*p+1,0]

2:  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ ∧ 2 c d-b e≠0

Derivation: Piecewise constant extraction

Basis: If  (b^2)-4 a c==0, then (∂_x)((((a+b x+c (x^2)))^p)/((((b/2)+c x))^(2 p)))==0

Rule 1.2.1.2.2.2.2.2: If  (b^2)-4 a c==0 ∧ p∉ℤ ∧ 2 c d-b e≠0, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  ((((a+b x+c (x^2)))^(FracPart[p]))/((c^(IntPart[p])) ((((b/2)+c x))^(2 FracPart[p]))))∫(((d+e x))^m) ((((b/2)+c x))^(2 p))dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (a+b*x+c*x^2)^FracPart[p]/(c^IntPart[p]*(b/2+c*x)^(2*FracPart[p]))*Int[(d+e*x)^m*(b/2+c*x)^(2*p),x] /;
FreeQ[{a,b,c,d,e,m,p},x] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]] && NeQ[2*c*d-b*e,0]

3.  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0

0:  ∫(((e x))^m) (((b x+c (x^2)))^p)dx  when p∈ℤ

Derivation: Algebraic simplification

Rule 1.2.1.2.3.0: If  p∈ℤ, then

∫(((e x))^m) (((b x+c (x^2)))^p)dx  ⟶  (1/(e^p)) ∫(((e x))^(m+p)) (((b+c x))^p)dx

Program code:

Int[(e_.*x_)^m_.*(b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  1/e^p*Int[(e*x)^(m+p)*(b+c*x)^p,x] /;
FreeQ[{b,c,e,m},x] && IntegerQ[p]

1:  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0

Reference: G&R 2.181.1, CRC 119 with c (d^2)-b d e+a (e^2)==0 ∧ m+p==0

Derivation: Special quadratic recurrence 2a or 3a with m+p==0

Rule 1.2.1.2.3.2.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p==0, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  ((e (((d+e x))^(m-1)) (((a+b x+c (x^2)))^(p+1)))/(c (p+1)))

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^(m-1)*(a+b*x+c*x^2)^(p+1)/(c*(p+1)) /;
FreeQ[{a,b,c,d,e,m,p},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]] && EqQ[m+p,0]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^(m-1)*(a+c*x^2)^(p+1)/(c*(p+1)) /;
FreeQ[{a,c,d,e,m,p},x] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && EqQ[m+p,0]

2:  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+2 p+2==0

Reference: G&R 2.181.4.4

Derivation: Special quadratic recurrence 2b or 3b with m+2 p+2==0

Note: If  m+2 p+2==0 and m≠0, then p+1≠0.

Rule 1.2.1.2.3.2.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+2 p+2==0, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  ((e (((d+e x))^m) (((a+b x+c (x^2)))^(p+1)))/((p+1)(2 c d-b e)))

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^m*(a+b*x+c*x^2)^(p+1)/((p+1)*(2*c*d-b*e)) /;
FreeQ[{a,b,c,d,e,m,p},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]] && EqQ[m+2*p+2,0]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^m*(a+c*x^2)^(p+1)/(2*c*d*(p+1)) /;
FreeQ[{a,c,d,e,m,p},x] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && EqQ[m+2*p+2,0]

3:  ∫(((d+e x))^2) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ p<-1

Derivation: Special quadratic recurrence 2a

Rule 1.2.1.2.3.2.3: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ p<-1, then

∫(((d+e x))^2)(((a+b x+c (x^2)))^p)dx  ⟶  ((e (d+e x) (((a+b x+c (x^2)))^(p+1)))/(c (p+1)))-(((e^2) (p+2))/(c (p+1)))∫(((a+b x+c (x^2)))^(p+1))dx

Program code:

Int[(d_.+e_.*x_)^2*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)*(a+b*x+c*x^2)^(p+1)/(c*(p+1)) - e^2*(p+2)/(c*(p+1))*Int[(a+b*x+c*x^2)^(p+1),x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]] && LtQ[p,-1]

Int[(d_+e_.*x_)^2*(a_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)*(a+c*x^2)^(p+1)/(c*(p+1)) - e^2*(p+2)/(c*(p+1))*Int[(a+c*x^2)^(p+1),x] /;
FreeQ[{a,c,d,e,p},x] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && LtQ[p,-1]

4:  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m∈ℤ ∧ (0<-m<p ∨ p<-m<0)

Derivation: Algebraic simplification

Basis: If  c (d^2)-b d e+a (e^2)==0, then d+e x==((a+b x+c (x^2))/((a/d)+((c x)/e)))

Basis: If  c (d^2)+a (e^2)==0, then d+e x==(((d^2)(a+c (x^2)))/(a(d-e x)))

Rule 1.2.1.2.3.2.4: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m∈ℤ ∧ (0<-m<p ∨ p<-m<0), then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  ∫((((a+b x+c (x^2)))^(m+p))/((((a/d)+((c x)/e)))^m))dx

Program code:

Int[(d_+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  Int[(a+b*x+c*x^2)^(m+p)/(a/d+c*x/e)^m,x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]] && IntegerQ[m] && 
  RationalQ[p] && (LtQ[0,-m,p] || LtQ[p,-m,0]) && NeQ[m,2] && NeQ[m,-1]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  d^(2*m)/a^m*Int[(a+c*x^2)^(m+p)/(d-e*x)^m,x] /;
FreeQ[{a,c,d,e,m,p},x] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && IntegerQ[m] && 
  RationalQ[p] && (LtQ[0,-m,p] || LtQ[p,-m,0]) && NeQ[m,2] && NeQ[m,-1]

5:  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p∈(SuperPlus[ℤ])

Reference: G&R 2.181.1, CRC 119 with a (e^2)-b d e+c (d^2)==0

Derivation: Special quadratic recurrence 3a

Note: If  p∉ℤ ∧ m+p∈(SuperPlus[ℤ]), then m+2 p+1≠0.

Rule 1.2.1.2.3.2.5: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+p∈(SuperPlus[ℤ]), then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  
((e (((d+e x))^(m-1)) (((a+b x+c (x^2)))^(p+1)))/(c (m+2 p+1)))+(((m+p)(2 c d-b e))/(c (m+2 p+1)))∫(((d+e x))^(m-1)) (((a+b x+c (x^2)))^p)dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^(m-1)*(a+b*x+c*x^2)^(p+1)/(c*(m+2*p+1)) + 
  Simplify[m+p]*(2*c*d-b*e)/(c*(m+2*p+1))*Int[(d+e*x)^(m-1)*(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,m,p},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]] && IGtQ[Simplify[m+p],0]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^(m-1)*(a+c*x^2)^(p+1)/(c*(m+2*p+1)) + 
  2*c*d*Simplify[m+p]/(c*(m+2*p+1))*Int[(d+e*x)^(m-1)*(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e,m,p},x] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && IGtQ[Simplify[m+p],0]

6:  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+2 p+2∈(SuperMinus[ℤ])

Reference: G&R 2.181.4.4

Derivation: Special quadratic recurrence 3b

Note: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0, then 2 c d-b e≠0.

Note: If  p∉ℤ ∧ m+2 p+2∈(SuperMinus[ℤ]), then m+p+1≠0.

Rule 1.2.1.2.3.2.6: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ m+2 p+2∈(SuperMinus[ℤ]), then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  
-((e (((d+e x))^m) (((a+b x+c (x^2)))^(p+1)))/((m+p+1)(2 c d-b e)))+((c (m+2 p+2))/((m+p+1)(2 c d-b e)))∫(((d+e x))^(m+1)) (((a+b x+c (x^2)))^p)dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  -e*(d+e*x)^m*(a+b*x+c*x^2)^(p+1)/((m+p+1)*(2*c*d-b*e)) + 
  c*Simplify[m+2*p+2]/((m+p+1)*(2*c*d-b*e))*Int[(d+e*x)^(m+1)*(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,m,p},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]] && ILtQ[Simplify[m+2*p+2],0]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  -e*(d+e*x)^m*(a+c*x^2)^(p+1)/(2*c*d*(m+p+1)) + 
  Simplify[m+2*p+2]/(2*d*(m+p+1))*Int[(d+e*x)^(m+1)*(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e,m,p},x] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && ILtQ[Simplify[m+2*p+2],0]

7:  ∫(1/((Sqrt[d+e x]) (Sqrt[a+b x+c (x^2)])))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0

Derivation: Integration by substitution

Basis: If  c (d^2)-b d e+a (e^2)==0, then (1/((Sqrt[d+e x]) (Sqrt[a+b x+c (x^2)])))==2 e Subst[(1/(2 c d-b e+(e^2) (x^2))),x,((Sqrt[a+b x+c (x^2)])/(Sqrt[d+e x]))] (∂_x)((Sqrt[a+b x+c (x^2)])/(Sqrt[d+e x]))

Rule 1.2.1.2.3.2.7: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0, then

∫(1/((Sqrt[d+e x]) (Sqrt[a+b x+c (x^2)])))dx  ⟶  2 e Subst[∫(1/(2 c d-b e+(e^2) (x^2)))dx,x,((Sqrt[a+b x+c (x^2)])/(Sqrt[d+e x]))]

Program code:

Int[1/(Sqrt[d_.+e_.*x_]*Sqrt[a_.+b_.*x_+c_.*x_^2]),x_Symbol] :=
  2*e*Subst[Int[1/(2*c*d-b*e+e^2*x^2),x],x,Sqrt[a+b*x+c*x^2]/Sqrt[d+e*x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0]

Int[1/(Sqrt[d_+e_.*x_]*Sqrt[a_+c_.*x_^2]),x_Symbol] :=
  2*e*Subst[Int[1/(2*c*d+e^2*x^2),x],x,Sqrt[a+c*x^2]/Sqrt[d+e*x]] /;
FreeQ[{a,c,d,e},x] && EqQ[c*d^2+a*e^2,0]

8.  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p>0 ∧ m<0

1:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p>0 ∧ (m<-2 ∨ m+2 p+1==0) ∧ m+p+1≠0

Reference: G&R 2.265b

Derivation: Special quadratic recurrence 1a

Rule 1.2.1.2.3.2.8.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p>0 ∧ (m<-2 ∨ m+2 p+1==0) ∧ m+p+1≠0, then

∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  ⟶  (((((d+e x))^(m+1)) (((a+b x+c (x^2)))^p))/(e (m+p+1)))-((c p)/((e^2) (m+p+1)))∫(((d+e x))^(m+2)) (((a+b x+c (x^2)))^(p-1))dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^(m+1)*(a+b*x+c*x^2)^p/(e*(m+p+1)) - 
  c*p/(e^2*(m+p+1))*Int[(d+e*x)^(m+2)*(a+b*x+c*x^2)^(p-1),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && GtQ[p,0] && (LtQ[m,-2] || EqQ[m+2*p+1,0]) && NeQ[m+p+1,0] && IntegerQ[2*p]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^(m+1)*(a+c*x^2)^p/(e*(m+p+1)) - 
  c*p/(e^2*(m+p+1))*Int[(d+e*x)^(m+2)*(a+c*x^2)^(p-1),x] /;
FreeQ[{a,c,d,e},x] && EqQ[c*d^2+a*e^2,0] && GtQ[p,0] && (LtQ[m,-2] || EqQ[m+2*p+1,0]) && NeQ[m+p+1,0] && IntegerQ[2*p]

2:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p>0 ∧ (-2≤m<0 ∨ m+p+1==0) ∧ m+2p+1≠0

Derivation: Special quadratic recurrence 1b

Rule 1.2.1.2.3.2.8.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p>0 ∧ (-2≤m<0 ∨ m+p+1==0) ∧ m+2p+1≠0, then

∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  ⟶  
(((((d+e x))^(m+1)) (((a+b x+c (x^2)))^p))/(e(m+2 p+1)))-((p(2 c d-b e))/((e^2)(m+2 p+1)))∫(((d+e x))^(m+1)) (((a+b x+c (x^2)))^(p-1))dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^(m+1)*(a+b*x+c*x^2)^p/(e*(m+2*p+1)) - 
  p*(2*c*d-b*e)/(e^2*(m+2*p+1))*Int[(d+e*x)^(m+1)*(a+b*x+c*x^2)^(p-1),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && GtQ[p,0] && (LeQ[-2,m,0] || EqQ[m+p+1,0]) && NeQ[m+2*p+1,0] && IntegerQ[2*p]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^(m+1)*(a+c*x^2)^p/(e*(m+2*p+1)) - 
  2*c*d*p/(e^2*(m+2*p+1))*Int[(d+e*x)^(m+1)*(a+c*x^2)^(p-1),x] /;
FreeQ[{a,c,d,e},x] && EqQ[c*d^2+a*e^2,0] && GtQ[p,0] && (LeQ[-2,m,0] || EqQ[m+p+1,0]) && NeQ[m+2*p+1,0] && IntegerQ[2*p]

9.  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p<-1 ∧ m>0

1:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p<-1 ∧ 0<m<1

Derivation: Special quadratic recurrence 2b

Rule 1.2.1.2.3.2.9.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p<-1 ∧ 0<m<1, then

∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  ⟶  
(((2 c d-b e)(((d+e x))^m)(((a+b x+c (x^2)))^(p+1)))/(e(p+1)((b^2)-4 a c) ))-(((2 c d-b e) (m+2 p+2))/((p+1)((b^2)-4 a c) ))∫(((d+e x))^(m-1)) (((a+b x+c (x^2)))^(p+1))dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (2*c*d-b*e)*(d+e*x)^m*(a+b*x+c*x^2)^(p+1)/(e*(p+1)*(b^2-4*a*c)) - 
  (2*c*d-b*e)*(m+2*p+2)/((p+1)*(b^2-4*a*c))*Int[(d+e*x)^(m-1)*(a+b*x+c*x^2)^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && LtQ[p,-1] && LtQ[0,m,1] && IntegerQ[2*p]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  -d*(d+e*x)^m*(a+c*x^2)^(p+1)/(2*a*e*(p+1)) + 
  d*(m+2*p+2)/(2*a*(p+1))*Int[(d+e*x)^(m-1)*(a+c*x^2)^(p+1),x] /;
FreeQ[{a,c,d,e},x] && EqQ[c*d^2+a*e^2,0] && LtQ[p,-1] && LtQ[0,m,1] && IntegerQ[2*p]

2:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p<-1 ∧ m>1

Derivation: Special quadratic recurrence 2a

Rule 1.2.1.2.2.3.9.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p<-1 ∧ m>1, then

∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  ⟶  
((e(((d+e x))^(m-1)) (((a+b x+c (x^2)))^(p+1)))/(c(p+1)))-(((e^2) (m+p))/(c(p+1)))∫(((d+e x))^(m-2)) (((a+b x+c (x^2)))^(p+1))dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^(m-1)*(a+b*x+c*x^2)^(p+1)/(c*(p+1)) - 
  e^2*(m+p)/(c*(p+1))*Int[(d+e*x)^(m-2)*(a+b*x+c*x^2)^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && LtQ[p,-1] && GtQ[m,1] && IntegerQ[2*p]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^(m-1)*(a+c*x^2)^(p+1)/(c*(p+1)) - 
  e^2*(m+p)/(c*(p+1))*Int[(d+e*x)^(m-2)*(a+c*x^2)^(p+1),x] /;
FreeQ[{a,c,d,e},x] && EqQ[c*d^2+a*e^2,0] && LtQ[p,-1] && GtQ[m,1] && IntegerQ[2*p]

10:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ m>1 ∧ m+2 p+1≠0

Reference: G&R 2.181.1, CRC 119 with a (e^2)-b d e+c (d^2)==0

Derivation: Special quadratic recurrence 3a

Rule 1.2.1.2.3.2.10: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ m>1 ∧ m+2 p+1≠0, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  
((e (((d+e x))^(m-1)) (((a+b x+c (x^2)))^(p+1)))/(c (m+2 p+1)))+(((m+p)(2 c d-b e))/(c (m+2 p+1)))∫(((d+e x))^(m-1)) (((a+b x+c (x^2)))^p)dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^(m-1)*(a+b*x+c*x^2)^(p+1)/(c*(m+2*p+1)) + 
  (m+p)*(2*c*d-b*e)/(c*(m+2*p+1))*Int[(d+e*x)^(m-1)*(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && GtQ[m,1] && NeQ[m+2*p+1,0] && IntegerQ[2*p]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^(m-1)*(a+c*x^2)^(p+1)/(c*(m+2*p+1)) + 
  2*c*d*(m+p)/(c*(m+2*p+1))*Int[(d+e*x)^(m-1)*(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e,p},x] && EqQ[c*d^2+a*e^2,0] && GtQ[m,1] && NeQ[m+2*p+1,0] && IntegerQ[2*p]

11:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ m<0 ∧ m+p+1≠0

Reference: G&R 2.181.4.4

Derivation: Special quadratic recurrence 3b

Note: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0, then 2 c d-b e≠0

Rule 1.2.1.2.3.2.11: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ m<0 ∧ m+p+1≠0, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  
-((e (((d+e x))^m) (((a+b x+c (x^2)))^(p+1)))/((m+p+1)(2 c d-b e)))+((c (m+2 p+2))/((m+p+1)(2 c d-b e)))∫(((d+e x))^(m+1)) (((a+b x+c (x^2)))^p)dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  -e*(d+e*x)^m*(a+b*x+c*x^2)^(p+1)/((m+p+1)*(2*c*d-b*e)) + 
  c*(m+2*p+2)/((m+p+1)*(2*c*d-b*e))*Int[(d+e*x)^(m+1)*(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && LtQ[m,0] && NeQ[m+p+1,0] && IntegerQ[2*p]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  -e*(d+e*x)^m*(a+c*x^2)^(p+1)/(2*c*d*(m+p+1)) + 
  (m+2*p+2)/(2*d*(m+p+1))*Int[(d+e*x)^(m+1)*(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e,p},x] && EqQ[c*d^2+a*e^2,0] && LtQ[m,0] && NeQ[m+p+1,0] && IntegerQ[2*p]

12.  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ

1:  ∫(((e x))^m)(((b x+c (x^2)))^p)dx  when p∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)(((((e x))^m)(((b x+c (x^2)))^p))/((x^(m+p)) (((b+c x))^p)))==0

Rule 1.2.1.2.3.2.12.1: If  p∉ℤ, then

∫(((e x))^m)(((b x+c (x^2)))^p)dx  ⟶  (((((e x))^m)(((b x+c (x^2)))^p))/((x^(m+p)) (((b+c x))^p)))∫(x^(m+p))(((b+c x))^p)dx

Program code:

Int[(e_.*x_)^m_*(b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (e*x)^m*(b*x+c*x^2)^p/(x^(m+p)*(b+c*x)^p)*Int[x^(m+p)*(b+c*x)^p,x] /;
FreeQ[{b,c,e,m},x] && Not[IntegerQ[p]]

??2:  ∫(((d+e x))^m)(((a+c (x^2)))^p)dx  when c (d^2)+a (e^2)==0 ∧ p∉ℤ ∧ a>0 ∧ d>0

Derivation: Algebraic simplification

Basis: If  c (d^2)+a (e^2)==0 ∧ a>0 ∧ d>0, then (((a+c (x^2)))^p)==(((a-((a (e^2) (x^2))/(d^2))))^p)==(((d+e x))^p) ((((a/d)+((c x)/e)))^p)

Rule 1.2.1.2.3.2.12.2: If  c (d^2)+a (e^2)==0 ∧ p∉ℤ ∧ a>0 ∧ d>0, then

∫(((d+e x))^m) (((a+c (x^2)))^p)dx  ⟶  ∫(((d+e x))^(m+p)) ((((a/d)+((c x)/e)))^p)dx

Program code:

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  Int[(d+e*x)^(m+p)*(a/d+c/e*x)^p,x] /;
FreeQ[{a,c,d,e,m,p},x] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && GtQ[a,0] && GtQ[d,0] && Not[IGtQ[m,0]]

?.  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ (m∈ℤ ∨ d>0)

1:  ∫(((d+e x))^m)(((a+c (x^2)))^p)dx  when c (d^2)+a (e^2)==0 ∧ p∉ℤ ∧ (m∈ℤ ∨ d>0) ∧ a>0

Derivation: Piecewise constant extraction

Basis: If  c (d^2)+a (e^2)==0, then (∂_x)((((a+c (x^2)))^(p+1))/((((1+((e x)/d)))^(p+1)) ((((a/d)+((c x)/e)))^(p+1))))==0

Basis: If  c (d^2)+a (e^2)==0 ∧ a>0, then ((((a+c (x^2)))^(p+1))/(((1+((e x)/d)))^(p+1)))==(a^(p+1)) (((((d-e x)/d)))^(p+1))

Note: If  c (d^2)-b d e+a (e^2)==0 ∧ m∈(SuperPlus[ℤ])∧ (3 p∈ℤ ∨ 4 p∈ℤ), then (((d+e x))^m) (((a+b x+c (x^2)))^p) is integrable in terms of non-hypergeometric functions.

Rule 1.2.1.2.3.2.12.3: If  c (d^2)+a (e^2)==0 ∧ p∉ℤ ∧ (m∈ℤ ∨ d>0) ∧ a>0, then

∫(((d+e x))^m) (((a+c (x^2)))^p)dx  ⟶  (((d^(m-1)) (((a+c (x^2)))^(p+1)))/((((1+((e x)/d)))^(p+1)) ((((a/d)+((c x)/e)))^(p+1))))∫(((1+((e x)/d)))^(m+p)) ((((a/d)+((c x)/e)))^p)dx
  ⟶  (((a^(p+1)) (d^(m-1)) (((((d-e x)/d)))^(p+1)))/((((a/d)+((c x)/e)))^(p+1)))∫(((1+((e x)/d)))^(m+p)) ((((a/d)+((c x)/e)))^p)dx

Program code:

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  a^(p+1)*d^(m-1)*((d-e*x)/d)^(p+1)/(a/d+c*x/e)^(p+1)*Int[(1+e*x/d)^(m+p)*(a/d+c/e*x)^p,x] /;
FreeQ[{a,c,d,e,m},x] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && (IntegerQ[m] || GtQ[d,0]) && GtQ[a,0] && 
  Not[IGtQ[m,0] && (IntegerQ[3*p] || IntegerQ[4*p])]

2:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ (m∈ℤ ∨ d>0)

Derivation: Piecewise constant extraction

Basis: If  c (d^2)-b d e+a (e^2)==0, then (∂_x)((((a+b x+c (x^2)))^p)/((((1+((e x)/d)))^p) ((((a/d)+((c x)/e)))^p)))==0

Note: If  c (d^2)-b d e+a (e^2)==0 ∧ m∈(SuperPlus[ℤ])∧ (3 p∈ℤ ∨ 4 p∈ℤ), then (((d+e x))^m) (((a+b x+c (x^2)))^p) is integrable in terms of non-hypergeometric functions.

Rule 1.2.1.2.3.2.12.3: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ (m∈ℤ ∨ d>0), then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  (((d^m) (((a+b x+c (x^2)))^(FracPart[p])))/((((1+((e x)/d)))^(FracPart[p])) ((((a/d)+((c x)/e)))^(FracPart[p]))))∫(((1+((e x)/d)))^(m+p)) ((((a/d)+((c x)/e)))^p)dx

Program code:

Int[(d_+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  d^m*(a+b*x+c*x^2)^FracPart[p]/((1+e*x/d)^FracPart[p]*(a/d+(c*x)/e)^FracPart[p])*Int[(1+e*x/d)^(m+p)*(a/d+c/e*x)^p,x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]] && (IntegerQ[m] || GtQ[d,0]) && 
  Not[IGtQ[m,0] && (IntegerQ[3*p] || IntegerQ[4*p])]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  d^(m-1)*(a+c*x^2)^(p+1)/((1+e*x/d)^(p+1)*(a/d+(c*x)/e)^(p+1))*Int[(1+e*x/d)^(m+p)*(a/d+c/e*x)^p,x] /;
FreeQ[{a,c,d,e,m},x] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && (IntegerQ[m] || GtQ[d,0]) && Not[IGtQ[m,0] && (IntegerQ[3*p] || IntegerQ[4*p])]

3:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ ¬(m∈ℤ ∨ d>0)

Derivation: Piecewise constant extraction

Basis: (∂_x)((((d+e x))^m)/(((1+((e x)/d)))^m))==0

Rule 1.2.1.2.3.2.12.3: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ ∧ ¬(m∈ℤ ∨ d>0), then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  (((d^(IntPart[m])) (((d+e x))^(FracPart[m])))/(((1+((e x)/d)))^(FracPart[m])))∫(((1+((e x)/d)))^m) (((a+b x+c (x^2)))^p)dx

Program code:

Int[(d_+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  d^IntPart[m]*(d+e*x)^FracPart[m]/(1+e*x/d)^FracPart[m]*Int[(1+e*x/d)^m*(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]] && Not[IntegerQ[m] || GtQ[d,0]]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  d^IntPart[m]*(d+e*x)^FracPart[m]/(1+e*x/d)^FracPart[m]*Int[(1+e*x/d)^m*(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e,m},x] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && Not[IntegerQ[m] || GtQ[d,0]]

4.  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when  (b^2)-4 a c≠0 ∧ 2 c d-b e==0

1.  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ m+2 p+3==0

1:  ∫(1/((d+e x) (a+b x+c (x^2))))dx  when (b^2)-4 a c≠0 ∧ 2 c d-b e==0

Derivation: Algebraic expansion

Basis: If  2 c d-b e==0, then (1/((d+e x) (a+b x+c (x^2))))==-((4 b c)/(d((b^2)-4 a c)(b+2 c x)))+(((b^2)(d+e x))/((d^2)((b^2)-4 a c)(a+b x+c (x^2))))

Rule 1.2.1.2.3.1.1: If  (b^2)-4 a c≠0 ∧ 2 c d-b e==0, then

∫(1/((d+e x) (a+b x+c (x^2))))dx  ⟶  -((4 b c)/(d((b^2)-4 a c)))∫(1/(b+2 c x))dx+((b^2)/((d^2)((b^2)-4 a c)))∫((d+e x)/(a+b x+c (x^2)))dx

Program code:

Int[1/((d_+e_.*x_)*(a_.+b_.*x_+c_.*x_^2)),x_Symbol] :=
  -4*b*c/(d*(b^2-4*a*c))*Int[1/(b+2*c*x),x] + 
  b^2/(d^2*(b^2-4*a*c))*Int[(d+e*x)/(a+b*x+c*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && EqQ[2*c*d-b*e,0]

2:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ m+2 p+3==0 ∧ p≠-1

Derivation: Derivative divides quadratic recurrence 2b or 3b with m+2 p+3==0

Rule 1.2.1.2.3.1.2: If  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ m+2 p+3==0 ∧ p≠-1, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  ((2c(((d+e x))^(m+1))(((a+b x+c (x^2)))^(p+1)))/(e(p+1)((b^2)-4 a c)))

Program code:

Int[(d_+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  2*c*(d+e*x)^(m+1)*(a+b*x+c*x^2)^(p+1)/(e*(p+1)*(b^2-4*a*c)) /;
FreeQ[{a,b,c,d,e,m,p},x] && NeQ[b^2-4*a*c,0] && EqQ[2*c*d-b*e,0] && EqQ[m+2*p+3,0] && NeQ[p,-1]

2:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.2.1.2.3.2: If  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ p∈(SuperPlus[ℤ]), then

∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  ⟶  ∫ExpandIntegrand[(((d+e x))^m)(((a+b x+c (x^2)))^p),x]dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(a+b*x+c*x^2)^p,x],x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b^2-4*a*c,0] && EqQ[2*c*d-b*e,0] && IGtQ[p,0] && Not[EqQ[m,3] && NeQ[p,1]]

3.  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ m+2 p+3≠0 ∧ p>0

1:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ m+2 p+3≠0 ∧ p>0 ∧ m<-1

Derivation: Derivative divides quadratic recurrence 1a

Derivation: Inverted integration by parts

Rule 1.2.1.2.3.3.1: If  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ m+2 p+3≠0 ∧ p>0 ∧ m<-1, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  (((((d+e x))^(m+1)) (((a+b x+c (x^2)))^p))/(e (m+1)))-((b p)/(d e (m+1)))∫(((d+e x))^(m+2)) (((a+b x+c (x^2)))^(p-1))dx

Program code:

Int[(d_+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  (d+e*x)^(m+1)*(a+b*x+c*x^2)^p/(e*(m+1)) - 
  b*p/(d*e*(m+1))*Int[(d+e*x)^(m+2)*(a+b*x+c*x^2)^(p-1),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && EqQ[2*c*d-b*e,0] && NeQ[m+2*p+3,0] && GtQ[p,0] && LtQ[m,-1] && 
  Not[IntegerQ[m/2] && LtQ[m+2*p+3,0]] && IntegerQ[2*p]

2:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ m+2 p+3≠0 ∧ p>0 ∧ m≮-1

Derivation: Derivative divides quadratic recurrence 1b

Rule 1.2.1.2.3.3.2: If  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ m+2 p+3≠0 ∧ p>0 ∧ m≮-1, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  (((((d+e x))^(m+1))(((a+b x+c (x^2)))^p))/(e(m+2 p+1)))-((d p((b^2)-4 a c))/(b e(m+2 p+1)))∫(((d+e x))^m) (((a+b x+c (x^2)))^(p-1))dx

Program code:

Int[(d_+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  (d+e*x)^(m+1)*(a+b*x+c*x^2)^p/(e*(m+2*p+1)) - 
  d*p*(b^2-4*a*c)/(b*e*(m+2*p+1))*Int[(d+e*x)^m*(a+b*x+c*x^2)^(p-1),x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b^2-4*a*c,0] && EqQ[2*c*d-b*e,0] && NeQ[m+2*p+3,0] && GtQ[p,0] && 
  Not[LtQ[m,-1]] && Not[IGtQ[(m-1)/2,0] && (Not[IntegerQ[p]] || LtQ[m,2*p])] && RationalQ[m] && IntegerQ[2*p]

4.  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ m+2 p+3≠0 ∧ p<-1

1:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ m+2 p+3≠0 ∧ p<-1 ∧ m>1

Derivation: Derivative divides quadratic recurrence 2a

Derivation: Integration by parts

Rule 1.2.1.2.3.4.1: If  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ m+2 p+3≠0 ∧ p<-1 ∧ m>1, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  ((d(((d+e x))^(m-1)) (((a+b x+c (x^2)))^(p+1)))/(b (p+1)))-((d e (m-1))/(b (p+1)))∫(((d+e x))^(m-2)) (((a+b x+c (x^2)))^(p+1))dx

Program code:

Int[(d_+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  d*(d+e*x)^(m-1)*(a+b*x+c*x^2)^(p+1)/(b*(p+1)) - 
  d*e*(m-1)/(b*(p+1))*Int[(d+e*x)^(m-2)*(a+b*x+c*x^2)^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && EqQ[2*c*d-b*e,0] && NeQ[m+2*p+3,0] && LtQ[p,-1] && GtQ[m,1] && IntegerQ[2*p]

2:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ m+2 p+3≠0 ∧ p<-1 ∧ m≯1

Derivation: Derivative divides quadratic recurrence 2b

Rule 1.2.1.2.3.4.2: If  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ m+2 p+3≠0 ∧ p<-1 ∧ m≯1, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  ((2c(((d+e x))^(m+1))(((a+b x+c (x^2)))^(p+1)))/(e(p+1)((b^2)-4 a c)))-((2c e(m+2 p+3))/(e(p+1)((b^2)-4 a c)))∫(((d+e x))^m) (((a+b x+c (x^2)))^(p+1))dx

Program code:

Int[(d_+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  2*c*(d+e*x)^(m+1)*(a+b*x+c*x^2)^(p+1)/(e*(p+1)*(b^2-4*a*c)) - 
  2*c*e*(m+2*p+3)/(e*(p+1)*(b^2-4*a*c))*Int[(d+e*x)^m*(a+b*x+c*x^2)^(p+1),x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b^2-4*a*c,0] && EqQ[2*c*d-b*e,0] && NeQ[m+2*p+3,0] && LtQ[p,-1] && Not[GtQ[m,1]] && RationalQ[m] && IntegerQ[2*p]

5:  ∫(1/((d+e x) (Sqrt[a+b x+c (x^2)])))dx  when  (b^2)-4 a c≠0 ∧ 2 c d-b e==0

Derivation: Integration by substitution

Basis: If  2 c d-b e==0, then (1/((d+e x) (Sqrt[a+b x+c (x^2)])))==4c Subst[(1/((b^2) e-4 a c e+4 c e (x^2))),x,(Sqrt[a+b x+c (x^2)])] (∂_x)(Sqrt[a+b x+c (x^2)])

Rule 1.2.1.2.3.5: If  (b^2)-4 a c≠0 ∧ 2 c d-b e==0, then

∫(1/((d+e x) (Sqrt[a+b x+c (x^2)])))dx  ⟶  4c Subst[∫(1/((b^2) e-4 a c e+4 c e (x^2)))dx,x,(Sqrt[a+b x+c (x^2)])]

Program code:

Int[1/((d_+e_.*x_)*Sqrt[a_.+b_.*x_+c_.*x_^2]),x_Symbol] :=
  4*c*Subst[Int[1/(b^2*e-4*a*c*e+4*c*e*x^2),x],x,Sqrt[a+b*x+c*x^2]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && EqQ[2*c*d-b*e,0]

6.  ∫((((d+e x))^m)/(Sqrt[a+b x+c (x^2)]))dx  when (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ (m^2)==(1/4)

1.  ∫((((d+e x))^m)/(Sqrt[a+b x+c (x^2)]))dx  when (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ (m^2)==(1/4) ∧ (c/((b^2)-4 a c))<0

1:  ∫(1/((Sqrt[d+e x]) (Sqrt[a+b x+c (x^2)])))dx  when  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ (c/((b^2)-4 a c))<0

Derivation: Integration by substitution

Basis: If  2 c d-b e==0 ∧ (c/((b^2)-4 a c))<0, then (1/((Sqrt[d+e x]) (Sqrt[a+b x+c (x^2)])))==(4/e) (Sqrt[-(c/((b^2)-4 a c))]) Subst[(1/(Sqrt[1-(((b^2) (x^4))/((d^2) ((b^2)-4 a c)))])),x,(Sqrt[d+e x])] (∂_x)(Sqrt[d+e x])

Rule 1.2.1.2.3.6.1.1: If  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ (c/((b^2)-4 a c))<0, then

∫(1/((Sqrt[d+e x]) (Sqrt[a+b x+c (x^2)])))dx  ⟶   (4/e) (Sqrt[-(c/((b^2)-4 a c))]) Subst[∫(1/(Sqrt[1-(((b^2) (x^4))/((d^2) ((b^2)-4 a c)))]))dx,x,(Sqrt[d+e x])]

Program code:

Int[1/(Sqrt[d_+e_.*x_]*Sqrt[a_.+b_.*x_+c_.*x_^2]),x_Symbol] :=
  4/e*Sqrt[-c/(b^2-4*a*c)]*Subst[Int[1/Sqrt[Simp[1-b^2*x^4/(d^2*(b^2-4*a*c)),x]],x],x,Sqrt[d+e*x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && EqQ[2*c*d-b*e,0] && LtQ[c/(b^2-4*a*c),0]

2:  ∫((Sqrt[d+e x])/(Sqrt[a+b x+c (x^2)]))dx  when  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ (c/((b^2)-4 a c))<0

Derivation: Integration by substitution

Basis: If  2 c d-b e==0 ∧ (c/((b^2)-4 a c))<0, then ((Sqrt[d+e x])/(Sqrt[a+b x+c (x^2)]))==(4/e) (Sqrt[-(c/((b^2)-4 a c))]) Subst[((x^2)/(Sqrt[1-(((b^2) (x^4))/((d^2) ((b^2)-4 a c)))])),x,(Sqrt[d+e x])] (∂_x)(Sqrt[d+e x])

Rule 1.2.1.2.3.6.1.2: If  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ (c/((b^2)-4 a c))<0, then

∫((Sqrt[d+e x])/(Sqrt[a+b x+c (x^2)]))dx  ⟶  (4/e) (Sqrt[-(c/((b^2)-4 a c))]) Subst[∫((x^2)/(Sqrt[1-(((b^2) (x^4))/((d^2) ((b^2)-4 a c)))]))dx,x,(Sqrt[d+e x])]

Program code:

Int[Sqrt[d_+e_.*x_]/Sqrt[a_.+b_.*x_+c_.*x_^2],x_Symbol] :=
  4/e*Sqrt[-c/(b^2-4*a*c)]*Subst[Int[x^2/Sqrt[Simp[1-b^2*x^4/(d^2*(b^2-4*a*c)),x]],x],x,Sqrt[d+e*x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && EqQ[2*c*d-b*e,0] && LtQ[c/(b^2-4*a*c),0]

2:  ∫((((d+e x))^m)/(Sqrt[a+b x+c (x^2)]))dx  when  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ (m^2)==(1/4) ∧ (c/((b^2)-4 a c))≮0

Derivation: Piecewise constant extraction

Basis: (∂_x)((Sqrt[-((c (a+b x+c (x^2)))/((b^2)-4 a c))])/(Sqrt[a+b x+c (x^2)]))==0

Rule 1.2.1.2.3.6.2: If  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ (m^2)==(1/4) ∧ (c/((b^2)-4 a c))≮0, then

∫((((d+e x))^m)/(Sqrt[a+b x+c (x^2)]))dx  ⟶  ((Sqrt[-((c (a+b x+c (x^2)))/((b^2)-4 a c))])/(Sqrt[a+b x+c (x^2)])) ∫((((d+e x))^m)/(Sqrt[-((a c)/((b^2)-4 a c))-((b c x)/((b^2)-4 a c))-(((c^2) (x^2))/((b^2)-4 a c))]))dx

Program code:

Int[(d_+e_.*x_)^m_/Sqrt[a_.+b_.*x_+c_.*x_^2],x_Symbol] :=
  Sqrt[-c*(a+b*x+c*x^2)/(b^2-4*a*c)]/Sqrt[a+b*x+c*x^2]*
    Int[(d+e*x)^m/Sqrt[-a*c/(b^2-4*a*c)-b*c*x/(b^2-4*a*c)-c^2*x^2/(b^2-4*a*c)],x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && EqQ[2*c*d-b*e,0] && EqQ[m^2,1/4]

7:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ m+2 p+3≠0 ∧ m>1 ∧ p≮-1

Derivation: Derivative divides quadratic recurrence 3a

Derivation: Integration by parts

Rule 1.2.1.2.3.7: If  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ m+2 p+3≠0 ∧ m>1 ∧ p≮-1, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  ((2d(((d+e x))^(m-1)) (((a+b x+c (x^2)))^(p+1)))/(b(m+2 p+1)))+(((d^2)(m-1)((b^2)-4 a c))/((b^2)(m+2 p+1)))∫(((d+e x))^(m-2)) (((a+b x+c (x^2)))^p)dx

Program code:

Int[(d_+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  2*d*(d+e*x)^(m-1)*(a+b*x+c*x^2)^(p+1)/(b*(m+2*p+1)) + 
  d^2*(m-1)*(b^2-4*a*c)/(b^2*(m+2*p+1))*Int[(d+e*x)^(m-2)*(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[b^2-4*a*c,0] && EqQ[2*c*d-b*e,0] && NeQ[m+2*p+3,0] && GtQ[m,1] && 
  NeQ[m+2*p+1,0] && (IntegerQ[2*p] || IntegerQ[m] && RationalQ[p] || OddQ[m])

8:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ m+2 p+3≠0 ∧ m<-1 ∧ p≯0

Derivation: Derivative divides quadratic recurrence 3b

Rule 1.2.1.2.3.8: If  (b^2)-4 a c≠0 ∧ 2 c d-b e==0 ∧ m+2 p+3≠0 ∧ m<-1 ∧ p≯0, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  -((2b d (((d+e x))^(m+1)) (((a+b x+c (x^2)))^(p+1)))/((d^2)(m+1)((b^2)-4 a c)))+(((b^2)(m+2 p+3))/((d^2)(m+1)((b^2)-4 a c)))∫(((d+e x))^(m+2)) (((a+b x+c (x^2)))^p)dx

Program code:

Int[(d_+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  -2*b*d*(d+e*x)^(m+1)*(a+b*x+c*x^2)^(p+1)/(d^2*(m+1)*(b^2-4*a*c)) + 
  b^2*(m+2*p+3)/(d^2*(m+1)*(b^2-4*a*c))*Int[(d+e*x)^(m+2)*(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[b^2-4*a*c,0] && EqQ[2*c*d-b*e,0] && NeQ[m+2*p+3,0] && LtQ[m,-1] && 
  (IntegerQ[2*p] || IntegerQ[m] && RationalQ[p] || IntegerQ[(m+2*p+3)/2])

9:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when  (b^2)-4 a c≠0 ∧ 2 c d-b e==0

Derivation: Integration by substitution

Basis: If  2 c d-b e==0, then F[a+b x+c (x^2)]==(1/e)Subst[F[a-((b^2)/(4 c))+((c (x^2))/(e^2))],x,d+e x] (∂_x)(d+e x)

Rule 1.2.1.2.3.9: If  (b^2)-4 a c≠0 ∧ 2 c d-b e==0, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  (1/e)Subst[∫(x^m) (((a-((b^2)/(4 c))+((c (x^2))/(e^2))))^p)dx,x,d+e x]

Program code:

Int[(d_+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  1/e*Subst[Int[x^m*(a-b^2/(4*c)+(c*x^2)/e^2)^p,x],x,d+e*x] /;
FreeQ[{a,b,c,d,e,m,p},x] && NeQ[b^2-4*a*c,0] && EqQ[2*c*d-b*e,0]

?:  ∫(1/((d+e x) (((a+c (x^2)))^(1/4))))dx  when  c (d^2)+2 a (e^2)==0 ∧ a<0

Reference: Eneström index number E688 in The Euler Archive

Rule 1.2.1.2.?: If  c (d^2)+2 a (e^2)==0 ∧ a<0, then

∫(1/((d+e x) (((a+c (x^2)))^(1/4))))dx  ⟶  (1/(2 (((-a))^(1/4)) e)) ArcTan[((((-1-((c (x^2))/a)))^(1/4))/(1-((c d x)/(2 a e))-(Sqrt[-1-((c (x^2))/a)])))]+(1/(4 (((-a))^(1/4)) e)) Log[((1-((c d x)/(2 a e))+(Sqrt[-1-((c (x^2))/a)])-(((-1-((c (x^2))/a)))^(1/4)))/(1-((c d x)/(2 a e))+(Sqrt[-1-((c (x^2))/a)])+(((-1-((c (x^2))/a)))^(1/4))))]

Program code:

Int[1/((d_+e_.*x_)*(a_.+c_.*x_^2)^(1/4)),x_Symbol] :=
  1/(2*(-a)^(1/4)*e)*ArcTan[(-1-c*x^2/a)^(1/4)/(1-c*d*x/(2*a*e)-Sqrt[-1-c*x^2/a])] + 
  1/(4*(-a)^(1/4)*e)*Log[(1-c*d*x/(2*a*e)+Sqrt[-1-c*x^2/a]-(-1-c*x^2/a)^(1/4))/
    (1-c*d*x/(2*a*e)+Sqrt[-1-c*x^2/a]+(-1-c*x^2/a)^(1/4))] /;
FreeQ[{a,c,d,e},x] && EqQ[c*d^2+2*a*e^2,0] && LtQ[a,0]

5.  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p∈ℤ ∧ (p>0 ∨ m∈ℤ)

1.  ∫(((d+e x))^m) (((a+c (x^2)))^p)dx  when  c (d^2)+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ])

1:  ∫(((d+e x))^m) (((a+c (x^2)))^p)dx  when c (d^2)+a (e^2)≠0 ∧ p-1∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m≤p

Derivation: Algebraic expansion and power rule for integration

Note: This rule removes the one degree term from the polynomial (((d+e x))^m).

Rule: If  c (d^2)+a (e^2)≠0 ∧ p-1∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])∧ m≤p, then

∫(((d+e x))^m) (((a+c (x^2)))^p)dx  ⟶  e m (d^(m-1)) ∫x (((a+c (x^2)))^p)dx+∫((((d+e x))^m)-e m (d^(m-1)) x) (((a+c (x^2)))^p)dx

  ⟶  ((e m (d^(m-1)) (((a+c (x^2)))^(p+1)))/(2 c(p+1)))+∫((((d+e x))^m)-e m (d^(m-1)) x) (((a+c (x^2)))^p)dx

Program code:

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  e*m*d^(m-1)*(a+c*x^2)^(p+1)/(2*c*(p+1)) + 
  Int[((d+e*x)^m-e*m*d^(m-1)*x)*(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && IGtQ[p,1] && IGtQ[m,0] && LeQ[m,p]

2:  ∫(((d+e x))^m) (((a+c (x^2)))^p)dx  when c (d^2)+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.2.1.2.5.2: If  c (d^2)+a (e^2)≠0 ∧ p∈(SuperPlus[ℤ]), then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  ∫ExpandIntegrand[(((d+e x))^m) (((a+b x+c (x^2)))^p),x]dx

Program code:

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(a+c*x^2)^p,x],x] /;
FreeQ[{a,c,d,e,m},x] && NeQ[c*d^2+a*e^2,0] && IGtQ[p,0]

2:  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p∈ℤ ∧ (p>0 ∨ a==0∧m∈ℤ)

Derivation: Algebraic expansion

Rule 1.2.1.2.5.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p∈ℤ ∧ (p>0 ∨ a==0∧m∈ℤ), then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  ∫ExpandIntegrand[(((d+e x))^m) (((a+b x+c (x^2)))^p),x]dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(a+b*x+c*x^2)^p,x],x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && IntegerQ[p] && (GtQ[p,0] || EqQ[a,0] && IntegerQ[m])

6.  ∫((((d+e x))^m)/(a+b x+c (x^2)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0

1.  ∫((((d+e x))^m)/(a+b x+c (x^2)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m>0

x.  ∫((Sqrt[d+e x])/(a+b x+c (x^2)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0

1:  ∫((Sqrt[d+e x])/(a+b x+c (x^2)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ (b^2)-4 a c<0

Derivation: Algebraic expansion

Basis: (Sqrt[d+e x])==((d+q+e x)/(2 (Sqrt[d+e x])))+((d-q+e x)/(2 (Sqrt[d+e x])))

Note: Resulting integrands are of the form ((A+B x)/((Sqrt[d+e x])(a+b x+c (x^2)))) where (A^2) c e-2 A B c d+(B^2) (b d-a e)==0.

Note: Although use of this rule when (b^2)-4 a c<0 results in antiderivatives superficially free of the imaginary unit but significantly more complicated than those produced by the following rule.

Rule 1.2.1.2.6.1.x.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ (b^2)-4 a c<0, let q->(Sqrt[((c (d^2)-b d e+a (e^2))/c)]), then

∫((Sqrt[d+e x])/(a+b x+c (x^2)))dx  ⟶  (1/2)∫((d+q+e x)/((Sqrt[d+e x])(a+b x+c (x^2))))dx+(1/2)∫((d-q+e x)/((Sqrt[d+e x])(a+b x+c (x^2))))dx

Program code:

(* Int[Sqrt[d_.+e_.*x_]/(a_.+b_.*x_+c_.*x_^2),x_Symbol] :=
  With[{q=Rt[(c*d^2-b*d*e+a*e^2)/c,2]},
  1/2*Int[(d+q+e*x)/(Sqrt[d+e*x]*(a+b*x+c*x^2)),x] + 
  1/2*Int[(d-q+e*x)/(Sqrt[d+e*x]*(a+b*x+c*x^2)),x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && LtQ[b^2-4*a*c,0] *)

(* Int[Sqrt[d_+e_.*x_]/(a_+c_.*x_^2),x_Symbol] :=
  With[{q=Rt[(c*d^2+a*e^2)/c,2]},
  1/2*Int[(d+q+e*x)/(Sqrt[d+e*x]*(a+c*x^2)),x] + 
  1/2*Int[(d-q+e*x)/(Sqrt[d+e*x]*(a+c*x^2)),x]] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && LtQ[-a*c,0] *)

2:  ∫((Sqrt[d+e x])/(a+b x+c (x^2)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ ¬((b^2)-4 a c<0)

Derivation: Algebraic expansion

Basis: If  q=(Sqrt[(b^2)-4 a c]), then  ((Sqrt[d+e x])/(a+b x+c (x^2)))==((2 c d-b e+e q)/(q(Sqrt[d+e x])(b-q+2 c x)))-((2 c d-b e-e q)/(q(Sqrt[d+e x])(b+q+2 c x)))

Rule 1.2.1.2.6.1.x.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ ¬((b^2)-4 a c<0), let q->(Sqrt[(b^2)-4 a c]), then

∫((Sqrt[d+e x])/(a+b x+c (x^2)))dx  ⟶  ((2 c d-b e+e q)/q)∫(1/((Sqrt[d+e x])(b-q+2 c x)))dx-((2 c d-b e-e q)/q)∫(1/((Sqrt[d+e x])(b+q+2 c x)))dx

Program code:

(* Int[Sqrt[d_.+e_.*x_]/(a_.+b_.*x_+c_.*x_^2),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  (2*c*d-b*e+e*q)/q*Int[1/(Sqrt[d+e*x]*(b-q+2*c*x)),x] - 
  (2*c*d-b*e-e*q)/q*Int[1/(Sqrt[d+e*x]*(b+q+2*c*x)),x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] (* && Not[LtQ[b^2-4*a*c,0]] *) *)

(* Int[Sqrt[d_+e_.*x_]/(a_+c_.*x_^2),x_Symbol] :=
  With[{q=Rt[-a*c,2]},
  (c*d+e*q)/(2*q)*Int[1/(Sqrt[d+e*x]*(-q+c*x)),x] - 
  (c*d-e*q)/(2*q)*Int[1/(Sqrt[d+e*x]*(+q+c*x)),x]] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] (* && Not[LtQ[-a*c,0]] *) *)

1:  ∫((Sqrt[d+e x])/(a+b x+c (x^2)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0

Derivation: Integration by substitution

Basis: (((d+e x))^m) F[x]==(2/e)Subst[(x^(2m+1)) F[((-d+(x^2))/e)],x,(Sqrt[d+e x])](∂_x)(Sqrt[d+e x])

Rule 1.2.1.2.6.1.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0

∫((Sqrt[d+e x])/(a+b x+c (x^2)))dx  ⟶  2e Subst[∫((x^2)/(c (d^2)-b d e+a (e^2)-(2 c d-b e) (x^2)+c (x^4)))dx,x,(Sqrt[d+e x])]

Program code:

Int[Sqrt[d_.+e_.*x_]/(a_.+b_.*x_+c_.*x_^2),x_Symbol] :=
  2*e*Subst[Int[x^2/(c*d^2-b*d*e+a*e^2-(2*c*d-b*e)*x^2+c*x^4),x],x,Sqrt[d+e*x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0]

Int[Sqrt[d_+e_.*x_]/(a_+c_.*x_^2),x_Symbol] :=
  2*e*Subst[Int[x^2/(c*d^2+a*e^2-2*c*d*x^2+c*x^4),x],x,Sqrt[d+e*x]] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0]

2.  ∫((((d+e x))^m)/(a+b x+c (x^2)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m>1

1:  ∫((((d+e x))^m)/(a+b x+c (x^2)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m∈ℤ ∧ m>1 ∧ (d≠0 ∨ m>2)

Derivation: Algebraic expansion

Rule 1.2.1.2.6.1.2.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m∈ℤ ∧ m>1 ∧ (d≠0 ∨ m>2), then

∫((((d+e x))^m)/(a+b x+c (x^2)))dx  ⟶  ∫PolynomialDivide[(((d+e x))^m),a+b x+c (x^2),x]dx

Program code:

Int[(d_.+e_.*x_)^m_/(a_.+b_.*x_+c_.*x_^2),x_Symbol] :=
  Int[PolynomialDivide[(d+e*x)^m,a+b*x+c*x^2,x],x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && IGtQ[m,1] && (NeQ[d,0] || GtQ[m,2])

Int[(d_+e_.*x_)^m_/(a_+c_.*x_^2),x_Symbol] :=
  Int[PolynomialDivide[(d+e*x)^m,a+c*x^2,x],x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && IGtQ[m,1] && (NeQ[d,0] || GtQ[m,2])

2:  ∫((((d+e x))^m)/(a+b x+c (x^2)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m>1

Reference: G&R 2.160.3, G&R 2.174.1, CRC 119

Derivation: Quadratic recurrence 3a with A=d, B=e, m=m-1 and p=-1

Note: G&R 2.174.1 is a special case of G&R 2.160.3.

Rule 1.2.1.2.6.1.2.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m>1, then

∫((((d+e x))^m)/(a+b x+c (x^2)))dx  ⟶  ((e(((d+e x))^(m-1)))/(c(m-1)))+(1/c)∫(((((d+e x))^(m-2)) (c (d^2)-a (e^2)+e (2 c d-b e) x))/(a+b x+c (x^2)))dx

Program code:

Int[(d_.+e_.*x_)^m_/(a_.+b_.*x_+c_.*x_^2),x_Symbol] :=
  e*(d+e*x)^(m-1)/(c*(m-1)) + 
  1/c*Int[(d+e*x)^(m-2)*Simp[c*d^2-a*e^2+e*(2*c*d-b*e)*x,x]/(a+b*x+c*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && GtQ[m,1]

Int[(d_+e_.*x_)^m_/(a_+c_.*x_^2),x_Symbol] :=
  e*(d+e*x)^(m-1)/(c*(m-1)) + 
  1/c*Int[(d+e*x)^(m-2)*Simp[c*d^2-a*e^2+2*c*d*e*x,x]/(a+c*x^2),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && GtQ[m,1]

2.  ∫((((d+e x))^m)/(a+b x+c (x^2)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m<0

1:  ∫(1/((d+e x) (a+b x+c (x^2))))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0

Derivation: Algebraic expansion

Basis: (1/((d+e x) (a+b x+c (x^2))))==((e^2)/((c (d^2)-b d e+a (e^2)) (d+e x)))+((c d-b e-c e x)/((c (d^2)-b d e+a (e^2)) (a+b x+c (x^2))))

Rule 1.2.1.2.6.2.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0, then

∫(1/((d+e x) (a+b x+c (x^2))))dx  ⟶  ((e^2)/(c (d^2)-b d e+a (e^2)))∫(1/(d+e x))dx+(1/(c (d^2)-b d e+a (e^2)))∫((c d-b e-c e x)/(a+b x+c (x^2)))dx

Program code:

Int[1/((d_.+e_.*x_)*(a_.+b_.*x_+c_.*x_^2)),x_Symbol] :=
  e^2/(c*d^2-b*d*e+a*e^2)*Int[1/(d+e*x),x] + 
  1/(c*d^2-b*d*e+a*e^2)*Int[(c*d-b*e-c*e*x)/(a+b*x+c*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0]

Int[1/((d_+e_.*x_)*(a_+c_.*x_^2)),x_Symbol] :=
  e^2/(c*d^2+a*e^2)*Int[1/(d+e*x),x] + 
  1/(c*d^2+a*e^2)*Int[(c*d-c*e*x)/(a+c*x^2),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0]

x.  ∫(1/((Sqrt[d+e x]) (a+b x+c (x^2))))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0

1:  ∫(1/((Sqrt[d+e x]) (a+b x+c (x^2))))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ (b^2)-4 a c<0

Derivation: Algebraic expansion

Basis: 1==((d+q+e x)/(2 q))-((d-q+e x)/(2 q))

Note: Resulting integrands are of the form ((A+B x)/((Sqrt[d+e x])(a+b x+c (x^2)))) where (A^2) c e-2 A B c d+(B^2) (b d-a e)==0.

Note: Although use of this rule when (b^2)-4 a c<0 results in antiderivatives superficially free of the imaginary unit but significantly more complicated than those produced by the following rule.

Rule 1.2.1.2.6.2.x.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ (b^2)-4 a c<0, let q->(Sqrt[((c (d^2)-b d e+a (e^2))/c)]), then

∫(1/((Sqrt[d+e x]) (a+b x+c (x^2))))dx  ⟶  (1/(2 q))∫((d+q+e x)/((Sqrt[d+e x])(a+b x+c (x^2))))dx-(1/(2 q))∫((d-q+e x)/((Sqrt[d+e x])(a+b x+c (x^2))))dx

Program code:

(* Int[1/(Sqrt[d_.+e_.*x_]*(a_.+b_.*x_+c_.*x_^2)),x_Symbol] :=
  With[{q=Rt[(c*d^2-b*d*e+a*e^2)/c,2]},
  1/(2*q)*Int[(d+q+e*x)/(Sqrt[d+e*x]*(a+b*x+c*x^2)),x] - 
  1/(2*q)*Int[(d-q+e*x)/(Sqrt[d+e*x]*(a+b*x+c*x^2)),x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && LtQ[b^2-4*a*c,0] *)

(* Int[1/(Sqrt[d_+e_.*x_]*(a_+c_.*x_^2)),x_Symbol] :=
  With[{q=Rt[(c*d^2+a*e^2)/c,2]},
  1/(2*q)*Int[(d+q+e*x)/(Sqrt[d+e*x]*(a+c*x^2)),x] - 
  1/(2*q)*Int[(d-q+e*x)/(Sqrt[d+e*x]*(a+c*x^2)),x]] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && LtQ[-a*c,0] *)

2:  ∫(1/((Sqrt[d+e x]) (a+b x+c (x^2))))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ ¬((b^2)-4 a c<0)

Derivation: Algebraic expansion

Basis: If  q=(Sqrt[(b^2)-4 a c]), then  (1/(a+b x+c (x^2)))==((2 c)/(q(b-q+2 c x)))-((2 c)/(q (b+q+2 c x)))

Rule 1.2.1.2.6.2.x.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ ¬((b^2)-4 a c<0), let q->(Sqrt[(b^2)-4 a c]), then

∫(1/((Sqrt[d+e x]) (a+b x+c (x^2))))dx  ⟶  ((2c)/q)∫(1/((Sqrt[d+e x]) (b-q+2 c x)))dx-((2c)/q)∫(1/((Sqrt[d+e x]) (b+q+2 c x)))dx

Program code:

(* Int[1/(Sqrt[d_.+e_.*x_]*(a_.+b_.*x_+c_.*x_^2)),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  2*c/q*Int[1/(Sqrt[d+e*x]*(b-q+2*c*x)),x] - 
  2*c/q*Int[1/(Sqrt[d+e*x]*(b+q+2*c*x)),x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] (* && Not[LtQ[b^2-4*a*c,0]] *) *)

(* Int[1/(Sqrt[d_+e_.*x_]*(a_+c_.*x_^2)),x_Symbol] :=
  With[{q=Rt[-a*c,2]},
  c/(2*q)*Int[1/(Sqrt[d+e*x]*(-q+c*x)),x] - 
  c/(2*q)*Int[1/(Sqrt[d+e*x]*(q+c*x)),x]] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] (* && Not[LtQ[-a*c,0]] *) *)

2:  ∫(1/((Sqrt[d+e x]) (a+b x+c (x^2))))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0

Derivation: Integration by substitution

Basis: (((d+e x))^m) F[x]==(2/e)Subst[(x^(2m+1)) F[((-d+(x^2))/e)],x,(Sqrt[d+e x])](∂_x)(Sqrt[d+e x])

Rule 1.2.1.2.6.2.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0

∫(1/((Sqrt[d+e x]) (a+b x+c (x^2))))dx  ⟶  2e Subst[∫(1/(c (d^2)-b d e+a (e^2)-(2 c d-b e) (x^2)+c (x^4)))dx,x,(Sqrt[d+e x])]

Program code:

Int[1/(Sqrt[d_.+e_.*x_]*(a_.+b_.*x_+c_.*x_^2)),x_Symbol] :=
  2*e*Subst[Int[1/(c*d^2-b*d*e+a*e^2-(2*c*d-b*e)*x^2+c*x^4),x],x,Sqrt[d+e*x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0]

Int[1/(Sqrt[d_+e_.*x_]*(a_+c_.*x_^2)),x_Symbol] :=
  2*e*Subst[Int[1/(c*d^2+a*e^2-2*c*d*x^2+c*x^4),x],x,Sqrt[d+e*x]] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0]

3:  ∫((((d+e x))^m)/(a+b x+c (x^2)))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m<-1

Reference: G&R 2.176, CRC 123

Derivation: Quadratic recurrence 3b with A=1, B=0 and p=-1

Rule 1.2.1.2.6.2.3: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m<-1, then

∫((((d+e x))^m)/(a+b x+c (x^2)))dx  ⟶  ((e (((d+e x))^(m+1)))/((m+1)(c (d^2)-b d e+a (e^2))))+(1/(c (d^2)-b d e+a (e^2))) ∫(((((d+e x))^(m+1)) (c d-b e-c e x))/(a+b x+c (x^2)))dx

Program code:

Int[(d_.+e_.*x_)^m_/(a_.+b_.*x_+c_.*x_^2),x_Symbol] :=
  e*(d+e*x)^(m+1)/((m+1)*(c*d^2-b*d*e+a*e^2)) + 
  1/(c*d^2-b*d*e+a*e^2)*Int[(d+e*x)^(m+1)*Simp[c*d-b*e-c*e*x,x]/(a+b*x+c*x^2),x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && LtQ[m,-1]

Int[(d_+e_.*x_)^m_/(a_+c_.*x_^2),x_Symbol] :=
  e*(d+e*x)^(m+1)/((m+1)*(c*d^2+a*e^2)) + 
  c/(c*d^2+a*e^2)*Int[(d+e*x)^(m+1)*(d-e*x)/(a+c*x^2),x] /;
FreeQ[{a,c,d,e,m},x] && NeQ[c*d^2+a*e^2,0] && LtQ[m,-1]

3:  ∫((((d+e x))^m)/(a+b x+c (x^2)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m∉ℤ

Derivation: Algebraic expansion

Basis: If  q=(Sqrt[(b^2)-4 a c]), then (1/(a+b z+c (z^2)))==((2c)/(q(b-q+2 c z)))-((2c)/(q(b+q+2 c z)))

Rule 1.2.1.2.6.3: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m∉ℤ, then

∫((((d+e x))^m)/(a+b x+c (x^2)))dx  ⟶  ∫(((d+e x))^m) ExpandIntegrand[(1/(a+b x+c (x^2))),x]dx

Program code:

Int[(d_.+e_.*x_)^m_/(a_.+b_.*x_+c_.*x_^2),x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m,1/(a+b*x+c*x^2),x],x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && Not[IntegerQ[m]]

Int[(d_+e_.*x_)^m_/(a_+c_.*x_^2),x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m,1/(a+c*x^2),x],x] /;
FreeQ[{a,c,d,e,m},x] && NeQ[c*d^2+a*e^2,0] && Not[IntegerQ[m]]

7:  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ b d+a e==0 ∧ c d+b e==0 ∧ m-p∈ℤ

Derivation: Piecewise constant extraction

Basis: If  b d+a e==0 ∧ c d+b e==0, then (∂_x)(((((d+e x))^p) (((a+b x+c (x^2)))^p))/(((a d+c e (x^3)))^p))==0

Rule 1.2.1.2.7: If  b d+a e==0 ∧ c d+b e==0 ∧ m-p∈ℤ, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  (((((d+e x))^(FracPart[p])) (((a+b x+c (x^2)))^(FracPart[p])))/(((a d+c e (x^3)))^(FracPart[p])))∫(((d+e x))^(m-p)) (((a d+c e (x^3)))^p)dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^FracPart[p]*(a+b*x+c*x^2)^FracPart[p]/(a*d+c*e*x^3)^FracPart[p]*Int[(d+e*x)^(m-p)*(a*d+c*e*x^3)^p,x] /;
FreeQ[{a,b,c,d,e,m,p},x] && EqQ[b*d+a*e,0] && EqQ[c*d+b*e,0] && IGtQ[m-p+1,0] && Not[IntegerQ[p]]

8.  ∫((((d+e x))^m)/(Sqrt[a+b x+c (x^2)]))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ (m^2)==(1/4)

1.  ∫((((d+e x))^m)/(Sqrt[b x+c (x^2)]))dx  when c d-b e≠0 ∧ 2 c d-b e≠0 ∧ (m^2)==(1/4)

1:  ∫((((d+e x))^m)/(Sqrt[b x+c (x^2)]))dx  when c d-b e≠0 ∧ 2 c d-b e≠0 ∧ (m^2)==(1/4) ∧ c<0 ∧ b∈ℝ

Derivation: Algebraic expansion

Basis:  If  c<0 ∧ b>0, then (Sqrt[b x+c (x^2)])==(Sqrt[x]) (Sqrt[b+c x])

Basis:  If  c<0 ∧ b<0, then (Sqrt[b x+c (x^2)])==(Sqrt[-x]) (Sqrt[-b-c x])

Basis:  If  c<0 ∧ b∈ℝ, then (Sqrt[b x+c (x^2)])==(Sqrt[b x]) (Sqrt[1+((c x)/b)])

Rule 1.2.1.2.8.1.1: If  c d-b e≠0 ∧ 2 c d-b e≠0 ∧ (m^2)==(1/4) ∧ c<0 ∧ b∈ℝ, then

∫((((d+e x))^m)/(Sqrt[b x+c (x^2)]))dx  ⟶  ∫((((d+e x))^m)/((Sqrt[b x]) (Sqrt[1+((c x)/b)]) ))dx

Program code:

Int[(d_.+e_.*x_)^m_/Sqrt[b_.*x_+c_.*x_^2],x_Symbol] :=
  Int[(d+e*x)^m/(Sqrt[b*x]*Sqrt[1+c/b*x]),x] /;
FreeQ[{b,c,d,e},x] && NeQ[c*d-b*e,0] && NeQ[2*c*d-b*e,0] && EqQ[m^2,1/4] && LtQ[c,0] && RationalQ[b]

2:  ∫((((d+e x))^m)/(Sqrt[b x+c (x^2)]))dx  when c d-b e≠0 ∧ 2 c d-b e≠0 ∧ (m^2)==(1/4)

Derivation: Piecewise constant extraction

Basis: (∂_x)(((Sqrt[x]) (Sqrt[b+c x]) )/(Sqrt[b x+c (x^2)]))==0

Rule 1.2.1.2.8.1.2: If  c d-b e≠0 ∧ 2 c d-b e≠0 ∧ (m^2)==(1/4), then

∫((((d+e x))^m)/(Sqrt[b x+c (x^2)]))dx  ⟶  (((Sqrt[x]) (Sqrt[b+c x]) )/(Sqrt[b x+c (x^2)]))∫((((d+e x))^m)/((Sqrt[x]) (Sqrt[b+c x]) ))dx

Program code:

Int[(d_.+e_.*x_)^m_/Sqrt[b_.*x_+c_.*x_^2],x_Symbol] :=
  Sqrt[x]*Sqrt[b+c*x]/Sqrt[b*x+c*x^2]*Int[(d+e*x)^m/(Sqrt[x]*Sqrt[b+c*x]),x] /;
FreeQ[{b,c,d,e},x] && NeQ[c*d-b*e,0] && NeQ[2*c*d-b*e,0] && EqQ[m^2,1/4]

2.  ∫((((e x))^m)/(Sqrt[a+b x+c (x^2)]))dx  when (b^2)-4 a c≠0 ∧ (m^2)==(1/4)

1:  ∫((x^m)/(Sqrt[a+b x+c (x^2)]))dx  when (b^2)-4 a c≠0 ∧ (m^2)==(1/4)

Derivation: Integration by substitution

Basis: (x^m) F[x]==2Subst[(x^(2m+1)) F[(x^2)],x,(Sqrt[x])](∂_x)(Sqrt[x])

Rule 1.2.1.2.8.2.1: If  (b^2)-4 a c≠0 ∧ (m^2)==(1/4), then

∫((x^m)/(Sqrt[a+b x+c (x^2)]))dx  ⟶  2Subst[∫((x^(2m+1))/(Sqrt[a+b (x^2)+c (x^4)]))dx,x,(Sqrt[x])]

Program code:

Int[x_^m_/Sqrt[a_+b_.*x_+c_.*x_^2],x_Symbol] :=
  2*Subst[Int[x^(2*m+1)/Sqrt[a+b*x^2+c*x^4],x],x,Sqrt[x]] /;
FreeQ[{a,b,c},x] && NeQ[b^2-4*a*c,0] && EqQ[m^2,1/4]

2:  ∫((((e x))^m)/(Sqrt[a+b x+c (x^2)]))dx  when (b^2)-4 a c≠0 ∧ (m^2)==(1/4)

Derivation: Piecewise constant extraction

Basis: (∂_x)((((e x))^m)/(x^m))==0

Rule 1.2.1.2.8.2.2: If  (b^2)-4 a c≠0 ∧ (m^2)==(1/4), then

∫((((e x))^m)/(Sqrt[a+b x+c (x^2)]))dx  ⟶  ((((e x))^m)/(x^m)) ∫((x^m)/(Sqrt[a+b x+c (x^2)]))dx

Int[(e_*x_)^m_/Sqrt[a_+b_.*x_+c_.*x_^2],x_Symbol] :=
  (e*x)^m/x^m*Int[x^m/Sqrt[a+b*x+c*x^2], x] /;
FreeQ[{a,b,c,e},x] && NeQ[b^2-4*a*c,0] && EqQ[m^2,1/4]

3:  ∫((((d+e x))^m)/(Sqrt[a+b x+c (x^2)]))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ (m^2)==(1/4)

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)(((((d+e x))^m)(Sqrt[-((c (a+b x+c (x^2)))/((b^2)-4 a c))]))/((Sqrt[a+b x+c (x^2)])(((((2 c (d+e x))/(2 c d-b e-e (Sqrt[(b^2)-4 a c])))))^m)))==0

Basis: ((((((2 c (d+e x))/(2 c d-b e-e (Sqrt[(b^2)-4 a c])))))^m)/(Sqrt[-((c (a+b x+c (x^2)))/((b^2)-4 a c))]))==((2(Sqrt[(b^2)-4 a c]))/c)Subst[((((1+((2 e (Sqrt[(b^2)-4 a c]) (x^2))/(2 c d-b e-e (Sqrt[(b^2)-4 a c])))))^m)/(Sqrt[1-(x^2)])),x,(Sqrt[((b+(Sqrt[(b^2)-4 a c])+2 c x)/(2 (Sqrt[(b^2)-4 a c])))])](∂_x)(Sqrt[((b+(Sqrt[(b^2)-4 a c])+2 c x)/(2 (Sqrt[(b^2)-4 a c])))])

Rule 1.2.1.2.8.3: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ (m^2)==(1/4), then

∫((((d+e x))^m)/(Sqrt[a+b x+c (x^2)]))dx  ⟶  (((((d+e x))^m)(Sqrt[-((c (a+b x+c (x^2)))/((b^2)-4 a c))]))/((Sqrt[a+b x+c (x^2)])(((((2 c (d+e x))/(2 c d-b e-e (Sqrt[(b^2)-4 a c])))))^m))) ∫((((((2 c (d+e x))/(2 c d-b e-e (Sqrt[(b^2)-4 a c])))))^m)/(Sqrt[-((c (a+b x+c (x^2)))/((b^2)-4 a c))]))dx

  ⟶  ((2(Sqrt[(b^2)-4 a c]) (((d+e x))^m) (Sqrt[-((c (a+b x+c (x^2)))/((b^2)-4 a c))]))/(c (Sqrt[a+b x+c (x^2)])(((((2 c (d+e x))/(2 c d-b e-e (Sqrt[(b^2)-4 a c])))))^m)))Subst[∫((((1+((2 e (Sqrt[(b^2)-4 a c]) (x^2))/(2 c d-b e-e (Sqrt[(b^2)-4 a c])))))^m)/(Sqrt[1-(x^2)]))dx,x,(Sqrt[((b+(Sqrt[(b^2)-4 a c])+2 c x)/(2 (Sqrt[(b^2)-4 a c])))])]

Rule 1.2.1.2.8.3: If  c (d^2)+a (e^2)≠0 ∧ (m^2)==(1/4), then

∫((((d+e x))^m)/(Sqrt[a+c (x^2)]))dx  ⟶  (((((d+e x))^m)(Sqrt[1+((c (x^2))/a)]))/((Sqrt[a+c (x^2)])(((((c (d+e x))/(c d-a e (Sqrt[-c/a])))))^m))) ∫((((((c (d+e x))/(c d-a e (Sqrt[-c/a])))))^m)/(Sqrt[((a+c (x^2))/a)]))dx

  ⟶  ((2 a (Sqrt[-c/a]) (((d+e x))^m) (Sqrt[1+((c (x^2))/a)]))/(c (Sqrt[a+c (x^2)])(((((c (d+e x))/(c d-a e (Sqrt[-c/a])))))^m)))Subst[∫((((1+((2 a e (Sqrt[-c/a]) (x^2))/(c d-a e (Sqrt[-c/a])))))^m)/(Sqrt[1-(x^2)]))dx,x,(Sqrt[((1-(Sqrt[-c/a]) x)/2)])]

Program code:

Int[(d_.+e_.*x_)^m_/Sqrt[a_.+b_.*x_+c_.*x_^2],x_Symbol] :=
  2*Rt[b^2-4*a*c,2]*(d+e*x)^m*Sqrt[-c*(a+b*x+c*x^2)/(b^2-4*a*c)]/
    (c*Sqrt[a+b*x+c*x^2]*(2*c*(d+e*x)/(2*c*d-b*e-e*Rt[b^2-4*a*c,2]))^m)*
    Subst[Int[(1+2*e*Rt[b^2-4*a*c,2]*x^2/(2*c*d-b*e-e*Rt[b^2-4*a*c,2]))^m/Sqrt[1-x^2],x],x,
      Sqrt[(b+Rt[b^2-4*a*c,2]+2*c*x)/(2*Rt[b^2-4*a*c,2])]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && EqQ[m^2,1/4]

Int[(d_+e_.*x_)^m_/Sqrt[a_+c_.*x_^2],x_Symbol] :=
  2*a*Rt[-c/a,2]*(d+e*x)^m*Sqrt[1+c*x^2/a]/(c*Sqrt[a+c*x^2]*(c*(d+e*x)/(c*d-a*e*Rt[-c/a,2]))^m)*
    Subst[Int[(1+2*a*e*Rt[-c/a,2]*x^2/(c*d-a*e*Rt[-c/a,2]))^m/Sqrt[1-x^2],x],x,Sqrt[(1-Rt[-c/a,2]*x)/2]] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && EqQ[m^2,1/4]

9.  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m+2 p+2==0

1:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m+2 p+2==0 ∧ p>0

Derivation: Quadratic recurrence 2a with A=d, B=e, m=m-1 and m+2 p+2==0 inverted

Rule 1.2.1.2.9.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m+2 p+2==0 ∧ p>0 ∧ p∉ℤ, then

∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  ⟶  
-(((((d+e x))^(m+1)) (d b-2 a e+(2 c d-b e) x)(((a+b x+c (x^2)))^p))/(2(m+1) (c (d^2)-b d e+a (e^2))))+((p ((b^2)-4 a c))/(2 (m+1) (c (d^2)-b d e+a (e^2))))∫(((d+e x))^(m+2))(((a+b x+c (x^2)))^(p-1))dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  -(d+e*x)^(m+1)*(d*b-2*a*e+(2*c*d-b*e)*x)*(a+b*x+c*x^2)^p/(2*(m+1)*(c*d^2-b*d*e+a*e^2)) + 
  p*(b^2-4*a*c)/(2*(m+1)*(c*d^2-b*d*e+a*e^2))*Int[(d+e*x)^(m+2)*(a+b*x+c*x^2)^(p-1),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && EqQ[m+2*p+2,0] && GtQ[p,0]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  -(d+e*x)^(m+1)*(-2*a*e+(2*c*d)*x)*(a+c*x^2)^p/(2*(m+1)*(c*d^2+a*e^2)) - 
  4*a*c*p/(2*(m+1)*(c*d^2+a*e^2))*Int[(d+e*x)^(m+2)*(a+c*x^2)^(p-1),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && EqQ[m+2*p+2,0] && GtQ[p,0]

2:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m+2 p+2==0 ∧ p<-1

Derivation: Quadratic recurrence 2a with A=d, B=e, m=m-1 and m+2 p+2==0

Rule 1.2.1.2.9.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m+2 p+2==0 ∧ p<-1, then

∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  ⟶  
(( (((d+e x))^(m-1)) (d b-2 a e+(2 c d-b e) x)(((a+b x+c (x^2)))^(p+1)))/((p+1) ((b^2)-4 a c)))-((2(2 p+3) (c (d^2)-b d e+a (e^2)))/((p+1)((b^2)-4 a c)))∫(((d+e x))^(m-2))(((a+b x+c (x^2)))^(p+1))dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^(m-1)*(d*b-2*a*e+(2*c*d-b*e)*x)*(a+b*x+c*x^2)^(p+1)/((p+1)*(b^2-4*a*c)) - 
  2*(2*p+3)*(c*d^2-b*d*e+a*e^2)/((p+1)*(b^2-4*a*c))*Int[(d+e*x)^(m-2)*(a+b*x+c*x^2)^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && EqQ[m+2*p+2,0] && LtQ[p,-1]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^(m-1)*(a*e-c*d*x)*(a+c*x^2)^(p+1)/(2*a*c*(p+1)) + 
  (2*p+3)*(c*d^2+a*e^2)/(2*a*c*(p+1))*Int[(d+e*x)^(m-2)*(a+c*x^2)^(p+1),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && EqQ[m+2*p+2,0] && LtQ[p,-1]

3:  ∫(1/((d+e x) (Sqrt[a+b x+c (x^2)])))dx  when  (b^2)-4 a c≠0 ∧ 2 c d-b e≠0

Reference: G&R 2.266.1, CRC 258

Reference: G&R 2.266.3, CRC 259

Derivation: Integration by substitution

Basis: (1/((d+e x) (Sqrt[a+b x+c (x^2)])))==-2Subst[(1/(4 c (d^2)-4 b d e+4 a (e^2)-(x^2))),x,((2 a e-b d-(2 c d-b e) x)/(Sqrt[a+b x+c (x^2)]))] (∂_x)((2 a e-b d-(2 c d-b e) x)/(Sqrt[a+b x+c (x^2)]))

Rule 1.2.1.2.9.3: If  (b^2)-4 a c≠0 ∧ 2 c d-b e≠0, then

∫(1/((d+e x) (Sqrt[a+b x+c (x^2)])))dx  ⟶  -2 Subst[∫(1/(4 c (d^2)-4 b d e+4 a (e^2)-(x^2)))dx,x,((2 a e-b d-(2 c d-b e) x)/(Sqrt[a+b x+c (x^2)]))]

Program code:

Int[1/((d_.+e_.*x_)*Sqrt[a_.+b_.*x_+c_.*x_^2]),x_Symbol] :=
  -2*Subst[Int[1/(4*c*d^2-4*b*d*e+4*a*e^2-x^2),x],x,(2*a*e-b*d-(2*c*d-b*e)*x)/Sqrt[a+b*x+c*x^2]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[2*c*d-b*e,0]

Int[1/((d_+e_.*x_)*Sqrt[a_+c_.*x_^2]),x_Symbol] :=
  -Subst[Int[1/(c*d^2+a*e^2-x^2),x],x,(a*e-c*d*x)/Sqrt[a+c*x^2]] /;
FreeQ[{a,c,d,e},x]

4:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m+2 p+2==0

Rule 1.2.1.2.9.4: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p∉ℤ ∧ m+2 p+2==0, then

∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  ⟶  
-(((b-(Sqrt[(b^2)-4 a c])+2 c x) (((d+e x))^(m+1)) (((a+b x+c (x^2)))^p))/((m+1)(2 c d-b e+e(Sqrt[(b^2)-4 a c]))((((((2 c d-b e+e(Sqrt[(b^2)-4 a c])) (b+(Sqrt[(b^2)-4 a c])+2 c x))/((2 c d-b e-e(Sqrt[(b^2)-4 a c])) (b-(Sqrt[(b^2)-4 a c])+2 c x)))))^p)))·
Hypergeometric2F1[m+1,-p,m+2,-((4 c (Sqrt[(b^2)-4 a c]) (d+e x))/((2 c d-b e-e(Sqrt[(b^2)-4 a c])) (b-(Sqrt[(b^2)-4 a c])+2 c x)))]

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  -(b-Rt[b^2-4*a*c,2]+2*c*x)*(d+e*x)^(m+1)*(a+b*x+c*x^2)^p/
    ((m+1)*(2*c*d-b*e+e*Rt[b^2-4*a*c,2])*
      ((2*c*d-b*e+e*Rt[b^2-4*a*c,2])*(b+Rt[b^2-4*a*c,2]+2*c*x)/((2*c*d-b*e-e*Rt[b^2-4*a*c,2])*(b-Rt[b^2-4*a*c,2]+2*c*x)))^p)*
    Hypergeometric2F1[m+1,-p,m+2,-4*c*Rt[b^2-4*a*c,2]*(d+e*x)/((2*c*d-b*e-e*Rt[b^2-4*a*c,2])*(b-Rt[b^2-4*a*c,2]+2*c*x))] /;
FreeQ[{a,b,c,d,e,m,p},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && Not[IntegerQ[p]] && EqQ[m+2*p+2,0]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  (Rt[-a*c,2]-c*x)*(d+e*x)^(m+1)*(a+c*x^2)^p/
    ((m+1)*(c*d+e*Rt[-a*c,2])*((c*d+e*Rt[-a*c,2])*(Rt[-a*c,2]+c*x)/((c*d-e*Rt[-a*c,2])*(-Rt[-a*c,2]+c*x)))^p)*
    Hypergeometric2F1[m+1,-p,m+2,2*c*Rt[-a*c,2]*(d+e*x)/((c*d-e*Rt[-a*c,2])*(Rt[-a*c,2]-c*x))] /;
FreeQ[{a,c,d,e,m,p},x] && NeQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && EqQ[m+2*p+2,0]

10.  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m+2 p+3==0

1:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m+2 p+3==0 ∧ p<-1

Derivation: Quadratic recurrence 2a with A=1, B=0 and m+2 p+3==0

Rule 1.2.1.2.10.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m+2 p+3==0 ∧ p<-1, then

∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  ⟶  
(( (((d+e x))^m) (b+2c x)(((a+b x+c (x^2)))^(p+1)))/((p+1) ((b^2)-4 a c)))+((m(2 c d-b e))/((p+1) ((b^2)-4 a c) ))∫(((d+e x))^(m-1))(((a+b x+c (x^2)))^(p+1))dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^m*(b+2*c*x)*(a+b*x+c*x^2)^(p+1)/((p+1)*(b^2-4*a*c)) + 
  m*(2*c*d-b*e)/((p+1)*(b^2-4*a*c))*Int[(d+e*x)^(m-1)*(a+b*x+c*x^2)^(p+1),x] /;
FreeQ[{a,b,c,d,e,m,p},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && EqQ[m+2*p+3,0] && LtQ[p,-1]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  -(d+e*x)^m*(2*c*x)*(a+c*x^2)^(p+1)/(4*a*c*(p+1)) - 
  m*(2*c*d)/(4*a*c*(p+1))*Int[(d+e*x)^(m-1)*(a+c*x^2)^(p+1),x] /;
FreeQ[{a,c,d,e,m,p},x] && NeQ[c*d^2+a*e^2,0] && EqQ[m+2*p+3,0] && LtQ[p,-1]

2:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m+2 p+3==0 ∧ p≰-1

Reference: G&R 2.176, CRC 123

Derivation: Quadratic recurrence 3b with A=1, B=0 and m+2 p+3==0

Rule 1.2.1.2.10.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m+2 p+3==0 ∧ p≰-1, then

∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  ⟶  
((e (((d+e x))^(m+1)) (((a+b x+c (x^2)))^(p+1)))/((m+1)(c (d^2)-b d e+a (e^2))))+(((2 c d-b e))/(2(c (d^2)-b d e+a (e^2)))) ∫(((d+e x))^(m+1))(((a+b x+c (x^2)))^p)dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^(m+1)*(a+b*x+c*x^2)^(p+1)/((m+1)*(c*d^2-b*d*e+a*e^2)) + 
  (2*c*d-b*e)/(2*(c*d^2-b*d*e+a*e^2))*Int[(d+e*x)^(m+1)*(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,m,p},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && EqQ[m+2*p+3,0]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^(m+1)*(a+c*x^2)^(p+1)/((m+1)*(c*d^2+a*e^2)) + 
  c*d/(c*d^2+a*e^2)*Int[(d+e*x)^(m+1)*(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e,m,p},x] && NeQ[c*d^2+a*e^2,0] && EqQ[m+2*p+3,0]

11.  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p>0

1:  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p>0 ∧ m<-1 ∧ m+2 p+1∉(SuperMinus[ℤ])

Derivation: Quadratic recurrence 1a with A=1 and B=0

Rule 1.2.1.2.11.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p>0 ∧ m<-1 ∧ m+2 p+1∉(SuperMinus[ℤ]), then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  
(((((d+e x))^(m+1)) (((a+b x+c (x^2)))^p))/(e (m+1)))-(p/(e (m+1)))∫(((d+e x))^(m+1)) (b+2 c x) (((a+b x+c (x^2)))^(p-1))dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^(m+1)*(a+b*x+c*x^2)^p/(e*(m+1)) - 
  p/(e*(m+1))*Int[(d+e*x)^(m+1)*(b+2*c*x)*(a+b*x+c*x^2)^(p-1),x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && GtQ[p,0] && 
  (IntegerQ[p] || LtQ[m,-1]) && NeQ[m,-1] && Not[ILtQ[m+2*p+1,0]] && IntQuadraticQ[a,b,c,d,e,m,p,x]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^(m+1)*(a+c*x^2)^p/(e*(m+1)) - 
  2*c*p/(e*(m+1))*Int[x*(d+e*x)^(m+1)*(a+c*x^2)^(p-1),x] /;
FreeQ[{a,c,d,e,m},x] && NeQ[c*d^2+a*e^2,0] && GtQ[p,0] && 
  (IntegerQ[p] || LtQ[m,-1]) && NeQ[m,-1] && Not[ILtQ[m+2*p+1,0]] && IntQuadraticQ[a,0,c,d,e,m,p,x]

2:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p>0 ∧ m+2 p∉(SuperMinus[ℤ])

Derivation: Quadratic recurrence 1b with A=1 and B=0

Derivation: Quadratic recurrence 1a with A=d, B=e and m=m-1

Rule 1.2.1.2.11.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p>0 ∧ m+2 p∉(SuperMinus[ℤ]), then

∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  ⟶  
(((((d+e x))^(m+1))(((a+b x+c (x^2)))^p))/(e(m+2 p+1)))-(p/(e(m+2 p+1)))∫(((d+e x))^m) (b d-2 a e+(2 c d-b e) x) (((a+b x+c (x^2)))^(p-1))dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^(m+1)*(a+b*x+c*x^2)^p/(e*(m+2*p+1)) - 
  p/(e*(m+2*p+1))*Int[(d+e*x)^m*Simp[b*d-2*a*e+(2*c*d-b*e)*x,x]*(a+b*x+c*x^2)^(p-1),x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && GtQ[p,0] && 
  NeQ[m+2*p+1,0] && (Not[RationalQ[m]] || LtQ[m,1]) && Not[ILtQ[m+2*p,0]] && IntQuadraticQ[a,b,c,d,e,m,p,x]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^(m+1)*(a+c*x^2)^p/(e*(m+2*p+1)) + 
  2*p/(e*(m+2*p+1))*Int[(d+e*x)^m*Simp[a*e-c*d*x,x]*(a+c*x^2)^(p-1),x] /;
FreeQ[{a,c,d,e,m},x] && NeQ[c*d^2+a*e^2,0] && GtQ[p,0] && 
  NeQ[m+2*p+1,0] && (Not[RationalQ[m]] || LtQ[m,1]) && Not[ILtQ[m+2*p,0]] && IntQuadraticQ[a,0,c,d,e,m,p,x]

12.  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p<-1

1.  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p<-1 ∧ m>0

1:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p<-1 ∧ 0<m<1

Derivation: Quadratic recurrence 2a with A=1 and B=0

Derivation: Quadratic recurrence 2b with A=d, B=e and m=m-1

Rule 1.2.1.2.12.1.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p<-1 ∧ 0<m<1, then

∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  ⟶  
(( (((d+e x))^m) (b+2c x)(((a+b x+c (x^2)))^(p+1)))/((p+1) ((b^2)-4 a c)))-(1/((p+1) ((b^2)-4 a c) ))∫(((d+e x))^(m-1))(b e m+2 c d (2 p+3)+2c e (m+2 p+3) x)(((a+b x+c (x^2)))^(p+1))dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^m*(b+2*c*x)*(a+b*x+c*x^2)^(p+1)/((p+1)*(b^2-4*a*c)) - 
  1/((p+1)*(b^2-4*a*c))*Int[(d+e*x)^(m-1)*(b*e*m+2*c*d*(2*p+3)+2*c*e*(m+2*p+3)*x)*(a+b*x+c*x^2)^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && 
  LtQ[p,-1] && GtQ[m,0] && (LtQ[m,1] || ILtQ[m+2*p+3,0] && NeQ[m,2]) && IntQuadraticQ[a,b,c,d,e,m,p,x]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  -x*(d+e*x)^m*(a+c*x^2)^(p+1)/(2*a*(p+1)) + 
  1/(2*a*(p+1))*Int[(d+e*x)^(m-1)*(d*(2*p+3)+e*(m+2*p+3)*x)*(a+c*x^2)^(p+1),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && 
  LtQ[p,-1] && GtQ[m,0] && (LtQ[m,1] || ILtQ[m+2*p+3,0] && NeQ[m,2]) && IntQuadraticQ[a,0,c,d,e,m,p,x]

2:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p<-1 ∧ m>1

Derivation: Quadratic recurrence 2a with A=d, B=e and m=m-1

Rule 1.2.1.2.12.1.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p<-1 ∧ m>1, then

∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  ⟶  
(( (((d+e x))^(m-1)) (d b-2 a e+(2 c d-b e) x)(((a+b x+c (x^2)))^(p+1)))/((p+1) ((b^2)-4 a c)))+
(1/((p+1) ((b^2)-4 a c) ))∫(((d+e x))^(m-2))(e (2 a e (m-1)+b d (2 p-m+4))-2 c (d^2) (2 p+3)+e(b e-2 d c) (m+2 p+2) x)(((a+b x+c (x^2)))^(p+1))dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^(m-1)*(d*b-2*a*e+(2*c*d-b*e)*x)*(a+b*x+c*x^2)^(p+1)/((p+1)*(b^2-4*a*c)) + 
  1/((p+1)*(b^2-4*a*c))*
    Int[(d+e*x)^(m-2)*
      Simp[e*(2*a*e*(m-1)+b*d*(2*p-m+4))-2*c*d^2*(2*p+3)+e*(b*e-2*d*c)*(m+2*p+2)*x,x]*
      (a+b*x+c*x^2)^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && LtQ[p,-1] && GtQ[m,1] && IntQuadraticQ[a,b,c,d,e,m,p,x]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^(m-1)*(a*e-c*d*x)*(a+c*x^2)^(p+1)/(2*a*c*(p+1)) + 
  1/((p+1)*(-2*a*c))*
    Int[(d+e*x)^(m-2)*Simp[a*e^2*(m-1)-c*d^2*(2*p+3)-d*c*e*(m+2*p+2)*x,x]*(a+c*x^2)^(p+1),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && LtQ[p,-1] && GtQ[m,1] && IntQuadraticQ[a,0,c,d,e,m,p,x]

2:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p<-1

Derivation: Quadratic recurrence 2b with A=1 and B=0

Rule 1.2.1.2.12.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p<-1, then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  
(((((d+e x))^(m+1)) (b c d-(b^2) e+2 a c e+c (2 c d-b e) x)(((a+b x+c (x^2)))^(p+1)))/((p+1)((b^2)-4 a c) (c (d^2)-b d e+a (e^2))))+(1/((p+1)((b^2)-4 a c) (c (d^2)-b d e+a (e^2))))·
∫(((d+e x))^m) (b c d e (2 p-m+2)+(b^2) (e^2) (m+p+2)-2 (c^2) (d^2) (2 p+3)-2 a c (e^2) (m+2 p+3)-c e(2 c d-b e) (m+2 p+4) x)(((a+b x+c (x^2)))^(p+1))dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  (d+e*x)^(m+1)*(b*c*d-b^2*e+2*a*c*e+c*(2*c*d-b*e)*x)*(a+b*x+c*x^2)^(p+1)/((p+1)*(b^2-4*a*c)*(c*d^2-b*d*e+a*e^2)) + 
  1/((p+1)*(b^2-4*a*c)*(c*d^2-b*d*e+a*e^2))*
    Int[(d+e*x)^m*
      Simp[b*c*d*e*(2*p-m+2)+b^2*e^2*(m+p+2)-2*c^2*d^2*(2*p+3)-2*a*c*e^2*(m+2*p+3)-c*e*(2*c*d-b*e)*(m+2*p+4)*x,x]*
      (a+b*x+c*x^2)^(p+1),x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && LtQ[p,-1] && IntQuadraticQ[a,b,c,d,e,m,p,x]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  -(d+e*x)^(m+1)*(a*e+c*d*x)*(a+c*x^2)^(p+1)/(2*a*(p+1)*(c*d^2+a*e^2)) + 
  1/(2*a*(p+1)*(c*d^2+a*e^2))*
    Int[(d+e*x)^m*Simp[c*d^2*(2*p+3)+a*e^2*(m+2*p+3)+c*e*d*(m+2*p+4)*x,x]*(a+c*x^2)^(p+1),x] /;
FreeQ[{a,c,d,e,m},x] && NeQ[c*d^2+a*e^2,0] && LtQ[p,-1] && IntQuadraticQ[a,0,c,d,e,m,p,x]

13:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m>1 ∧ m+2 p+1≠0

Reference: G&R 2.160.3, G&R 2.174.1, CRC 119

Derivation: Quadratic recurrence 3a with A=d, B=e and m=m-1

Note: G&R 2.174.1 is a special case of G&R 2.160.3.

Rule 1.2.1.2.13: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m>1 ∧ m+2 p+1≠0, then

∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  ⟶  
((e(((d+e x))^(m-1))(((a+b x+c (x^2)))^(p+1)))/(c (m+2 p+1)))+(1/(c (m+2 p+1)))∫(((d+e x))^(m-2)) (c (d^2)(m+2 p+1)-e (a e (m-1)+b d (p+1))+e (2 c d-b e) (m+p) x) (((a+b x+c (x^2)))^p)dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^(m-1)*(a+b*x+c*x^2)^(p+1)/(c*(m+2*p+1)) + 
  1/(c*(m+2*p+1))*
    Int[(d+e*x)^(m-2)*
      Simp[c*d^2*(m+2*p+1)-e*(a*e*(m-1)+b*d*(p+1))+e*(2*c*d-b*e)*(m+p)*x,x]*
      (a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,m,p},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && 
  If[RationalQ[m], GtQ[m,1], SumSimplerQ[m,-2]] && NeQ[m+2*p+1,0] && IntQuadraticQ[a,b,c,d,e,m,p,x]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^(m-1)*(a+c*x^2)^(p+1)/(c*(m+2*p+1)) + 
  1/(c*(m+2*p+1))*
    Int[(d+e*x)^(m-2)*Simp[c*d^2*(m+2*p+1)-a*e^2*(m-1)+2*c*d*e*(m+p)*x,x]*(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e,m,p},x] && NeQ[c*d^2+a*e^2,0] && 
  If[RationalQ[m], GtQ[m,1], SumSimplerQ[m,-2]] && NeQ[m+2*p+1,0] && IntQuadraticQ[a,0,c,d,e,m,p,x]

14:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m<-1

Reference: G&R 2.176, CRC 123

Derivation: Quadratic recurrence 3b with A=1 and B=0

Rule 1.2.1.2.14: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ m<-1, then

∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  ⟶  
((e (((d+e x))^(m+1)) (((a+b x+c (x^2)))^(p+1)))/((m+1)(c (d^2)-b d e+a (e^2))))+
(1/((m+1)(c (d^2)-b d e+a (e^2)))) ∫(((d+e x))^(m+1)) (c d (m+1)-b e (m+p+2)-c e (m+2 p+3) x)(((a+b x+c (x^2)))^p)dx

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^(m+1)*(a+b*x+c*x^2)^(p+1)/((m+1)*(c*d^2-b*d*e+a*e^2)) + 
  1/((m+1)*(c*d^2-b*d*e+a*e^2))*
    Int[(d+e*x)^(m+1)*Simp[c*d*(m+1)-b*e*(m+p+2)-c*e*(m+2*p+3)*x,x]*(a+b*x+c*x^2)^p,x] /;
FreeQ[{a,b,c,d,e,m,p},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && NeQ[m,-1] && 
  (LtQ[m,-1] && IntQuadraticQ[a,b,c,d,e,m,p,x] || SumSimplerQ[m,1] && IntegerQ[p] || ILtQ[Simplify[m+2*p+3],0])

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  e*(d+e*x)^(m+1)*(a+c*x^2)^(p+1)/((m+1)*(c*d^2+a*e^2)) + 
  c/((m+1)*(c*d^2+a*e^2))*
    Int[(d+e*x)^(m+1)*Simp[d*(m+1)-e*(m+2*p+3)*x,x]*(a+c*x^2)^p,x] /;
FreeQ[{a,c,d,e,m,p},x] && NeQ[c*d^2+a*e^2,0] && NeQ[m,-1] && 
  (LtQ[m,-1] && IntQuadraticQ[a,0,c,d,e,m,p,x] || SumSimplerQ[m,1] && IntegerQ[p] || ILtQ[Simplify[m+2*p+3],0])

15.  ∫((((a+b x+c (x^2)))^p)/(d+e x))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ 4 p∈ℤ

1.  ∫((((a+c (x^2)))^p)/(d+e x))dx  when c (d^2)+a (e^2)≠0 ∧ 4 p∈ℤ

1:  ∫(1/((d+e x) (((a+c (x^2)))^(1/4))))dx  when  c (d^2)+a (e^2)≠0

Derivation: Algebraic expansion

Basis: (1/(d+e x))==(d/((d^2)-(e^2) (x^2)))-((e x)/((d^2)-(e^2) (x^2)))

Rule 1.2.1.2.15.1.1: If  c (d^2)+a (e^2)≠0, then

∫(1/((d+e x) (((a+c (x^2)))^(1/4))))dx  ⟶  d∫(1/(((d^2)-(e^2) (x^2))(((a+c (x^2)))^(1/4))))dx-e∫(x/(((d^2)-(e^2) (x^2))(((a+c (x^2)))^(1/4))))dx

Program code:

Int[1/((d_+e_.*x_)*(a_+c_.*x_^2)^(1/4)),x_Symbol] :=
  d*Int[1/((d^2-e^2*x^2)*(a+c*x^2)^(1/4)),x] - e*Int[x/((d^2-e^2*x^2)*(a+c*x^2)^(1/4)),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0]

2:  ∫(1/((d+e x) (((a+c (x^2)))^(3/4))))dx  when  c (d^2)+a (e^2)≠0

Derivation: Algebraic expansion

Basis: (1/(d+e x))==(d/((d^2)-(e^2) (x^2)))-((e x)/((d^2)-(e^2) (x^2)))

Rule 1.2.1.2.15.1.2: If  c (d^2)+a (e^2)≠0, then

∫(1/((d+e x) (((a+c (x^2)))^(3/4))))dx  ⟶  d∫(1/(((d^2)-(e^2) (x^2))(((a+c (x^2)))^(3/4))))dx-e∫(x/(((d^2)-(e^2) (x^2))(((a+c (x^2)))^(3/4))))dx

Program code:

Int[1/((d_+e_.*x_)*(a_+c_.*x_^2)^(3/4)),x_Symbol] :=
  d*Int[1/((d^2-e^2*x^2)*(a+c*x^2)^(3/4)),x] - e*Int[x/((d^2-e^2*x^2)*(a+c*x^2)^(3/4)),x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0]

2.  ∫((((a+b x+c (x^2)))^p)/(d+e x))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ 4 p∈ℤ

1:  ∫((((a+b x+c (x^2)))^p)/(d+e x))dx  when 4 a-((b^2)/c)>0 ∧ 4 p∈ℤ

Derivation: Integration by substitution

Basis: If  4 a-((b^2)/c)>0, then (((a+b x+c (x^2)))^p) F[x]==(1/(2 c (((-((4  c)/((b^2)-4 a c))))^p))) Subst[(((1-((x^2)/((b^2)-4 a c))))^p) F[-(b/(2 c))+(x/(2 c))],x,b+2 c x] (∂_x)(b+2 c x)

Rule 1.2.1.2.15.2.1: If  4 a-((b^2)/c)>0 ∧ 4 p∈ℤ, then

∫((((a+b x+c (x^2)))^p)/(d+e x))dx  ⟶  (1/(((-((4  c)/((b^2)-4 a c))))^p)) Subst[∫((((1-((x^2)/((b^2)-4 a c))))^p)/(2 c d-b e+e x))dx,x,b+2 c x]

Program code:

Int[(a_.+b_.*x_+c_.*x_^2)^p_/(d_.+e_.*x_),x_Symbol] :=
  1/(-4*c/(b^2-4*a*c))^p*Subst[Int[Simp[1-x^2/(b^2-4*a*c),x]^p/Simp[2*c*d-b*e+e*x,x],x],x,b+2*c*x] /;
FreeQ[{a,b,c,d,e,p},x] && GtQ[4*a-b^2/c,0] && IntegerQ[4*p]

2:  ∫((((a+b x+c (x^2)))^p)/(d+e x))dx  when 4 a-((b^2)/c)≯0 ∧ 4 p∈ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((a+b x+c (x^2)))^p)/(((-((c (a+b x+c (x^2)))/((b^2)-4 a c))))^p))==0

Rule 1.2.1.2.15.2.2: If  4 a-((b^2)/c)≯0 ∧ 4 p∈ℤ, then

∫((((a+b x+c (x^2)))^p)/(d+e x))dx  ⟶  ((((a+b x+c (x^2)))^p)/(((-((c (a+b x+c (x^2)))/((b^2)-4 a c))))^p)) ∫((((-((a c)/((b^2)-4 a c))-((b c x)/((b^2)-4 a c))-(((c^2) (x^2))/((b^2)-4 a c))))^p)/(d+e x))dx

Program code:

Int[(a_.+b_.*x_+c_.*x_^2)^p_/(d_.+e_.*x_),x_Symbol] :=
  (a+b*x+c*x^2)^p/(-c*(a+b*x+c*x^2)/(b^2-4*a*c))^p*
    Int[(-a*c/(b^2-4*a*c)-b*c*x/(b^2-4*a*c)-c^2*x^2/(b^2-4*a*c))^p/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,p},x] && Not[GtQ[4*a-b^2/c,0]] && IntegerQ[4*p]

16.  ∫(1/((d+e x) (((a+b x+c (x^2)))^(1/3))))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0

1.  ∫(1/((d+e x) (((a+b x+c (x^2)))^(1/3))))dx  when 2 c d-b e≠0 ∧ (c^2) (d^2)-b c d e+(b^2) (e^2)-3 a c (e^2)==0

1:  ∫(1/((d+e x) (((a+b x+c (x^2)))^(1/3))))dx  when  2 c d-b e≠0 ∧ (c^2) (d^2)-b c d e+(b^2) (e^2)-3 a c (e^2)==0 ∧ c (e^2) (2 c d-b e)>0

Derived from formula for this class of Goursat pseudo-elliptic integrands contributed by Martin Welz on 19 September 2016

Rule 1.2.1.2.16.1.1: If  2 c d-b e≠0 ∧ (c^2) (d^2)-b c d e+(b^2) (e^2)-3 a c (e^2)==0 ∧ c (e^2) (2 c d-b e)>0, let q->(((3 c (e^2) (2 c d-b e)))^(1/3)), then

∫(1/((d+e x) (((a+b x+c (x^2)))^(1/3))))dx  ⟶  
-(((Sqrt[3]) c e ArcTan[(1/(Sqrt[3]))+((2 (c d-b e-c e x))/((Sqrt[3]) q (((a+b x+c (x^2)))^(1/3))))])/(q^2))-((3 c e Log[d+e x])/(2 (q^2)))+((3 c e Log[c d-b e-c e x-q (((a+b x+c (x^2)))^(1/3))])/(2 (q^2)))

Rule 1.2.1.2.16.1.1: If  c (d^2)-3 a (e^2)==0, let q->(((((6 (c^2) (e^2))/(d^2))))^(1/3)), then

∫(1/((d+e x) (((a+c (x^2)))^(1/3))))dx  ⟶  
-(((Sqrt[3]) c e ArcTan[(1/(Sqrt[3]))+((2 c (d-e x))/((Sqrt[3]) d q (((a+c (x^2)))^(1/3))))])/((d^2) (q^2)))-((3 c e Log[d+e x])/(2 (d^2) (q^2)))+((3 c e Log[c d-c e x-d q (((a+c (x^2)))^(1/3))])/(2 (d^2) (q^2)))

Program code:

Int[1/((d_.+e_.*x_)*(a_+b_.*x_+c_.*x_^2)^(1/3)),x_Symbol] :=
  With[{q=Rt[3*c*e^2*(2*c*d-b*e),3]},
  -Sqrt[3]*c*e*ArcTan[1/Sqrt[3]+2*(c*d-b*e-c*e*x)/(Sqrt[3]*q*(a+b*x+c*x^2)^(1/3))]/q^2 - 
  3*c*e*Log[d+e*x]/(2*q^2) + 
  3*c*e*Log[c*d-b*e-c*e*x-q*(a+b*x+c*x^2)^(1/3)]/(2*q^2)] /;
FreeQ[{a,b,c,d,e},x] && NeQ[2*c*d-b*e,0] && EqQ[c^2*d^2-b*c*d*e+b^2*e^2-3*a*c*e^2,0] && PosQ[c*e^2*(2*c*d-b*e)]

Int[1/((d_+e_.*x_)*(a_+c_.*x_^2)^(1/3)),x_Symbol] :=
  With[{q=Rt[6*c^2*e^2/d^2,3]},
  -Sqrt[3]*c*e*ArcTan[1/Sqrt[3]+2*c*(d-e*x)/(Sqrt[3]*d*q*(a+c*x^2)^(1/3))]/(d^2*q^2) - 
  3*c*e*Log[d+e*x]/(2*d^2*q^2) + 
  3*c*e*Log[c*d-c*e*x-d*q*(a+c*x^2)^(1/3)]/(2*d^2*q^2)] /;
FreeQ[{a,c,d,e},x] && EqQ[c*d^2-3*a*e^2,0]

2:  ∫(1/((d+e x) (((a+b x+c (x^2)))^(1/3))))dx  when  2 c d-b e≠0 ∧ (c^2) (d^2)-b c d e+(b^2) (e^2)-3 a c (e^2)==0 ∧ c (e^2) (2 c d-b e)≯0

Derived from formula for this class of Goursat pseudo-elliptic integrands contributed by Martin Welz on 19 September 2016

Rule 1.2.1.2.16.1.2: If  2 c d-b e≠0 ∧ (c^2) (d^2)-b c d e+(b^2) (e^2)-3 a c (e^2)==0 ∧ c (e^2) (2 c d-b e)≯0, let q->(((-3 c (e^2) (2 c d-b e)))^(1/3)), then

∫(1/((d+e x) (((a+b x+c (x^2)))^(1/3))))dx  ⟶  
-(((Sqrt[3]) c e ArcTan[(1/(Sqrt[3]))-((2 (c d-b e-c e x))/((Sqrt[3]) q (((a+b x+c (x^2)))^(1/3))))])/(q^2))-((3 c e Log[d+e x])/(2 (q^2)))+((3 c e Log[c d-b e-c e x+q (((a+b x+c (x^2)))^(1/3))])/(2 (q^2)))

Program code:

Int[1/((d_.+e_.*x_)*(a_+b_.*x_+c_.*x_^2)^(1/3)),x_Symbol] :=
  With[{q=Rt[-3*c*e^2*(2*c*d-b*e),3]},
  -Sqrt[3]*c*e*ArcTan[1/Sqrt[3]-2*(c*d-b*e-c*e*x)/(Sqrt[3]*q*(a+b*x+c*x^2)^(1/3))]/q^2 - 
  3*c*e*Log[d+e*x]/(2*q^2) + 
  3*c*e*Log[c*d-b*e-c*e*x+q*(a+b*x+c*x^2)^(1/3)]/(2*q^2)] /;
FreeQ[{a,b,c,d,e},x] && NeQ[2*c*d-b*e,0] && EqQ[c^2*d^2-b*c*d*e+b^2*e^2-3*a*c*e^2,0] && NegQ[c*e^2*(2*c*d-b*e)]

(* Int[1/((d_+e_.*x_)*(a_+c_.*x_^2)^(1/3)),x_Symbol] :=
  With[{q=Rt[-6*c^2*d*e^2,3]},
  -Sqrt[3]*c*e*ArcTan[1/Sqrt[3]-2*(c*d-c*e*x)/(Sqrt[3]*q*(a+c*x^2)^(1/3))]/q^2 - 
  3*c*e*Log[d+e*x]/(2*q^2) + 
  3*c*e*Log[c*d-c*e*x+q*(a+c*x^2)^(1/3)]/(2*q^2)] /;
FreeQ[{a,c,d,e},x] && EqQ[c*d^2-3*a*e^2,0] && NegQ[c^2*d*e^2] *)

2.  ∫(1/((d+e x) (((a+b x+c (x^2)))^(1/3))))dx  when (b^2)-4 a c≠0 ∧ (c^2) (d^2)-b c d e-2 (b^2) (e^2)+9 a c (e^2)==0

1.  ∫(1/((d+e x) (((a+c (x^2)))^(1/3))))dx  when c (d^2)+9 a (e^2)==0

1:  ∫(1/((d+e x) (((a+c (x^2)))^(1/3))))dx  when  c (d^2)+9 a (e^2)==0 ∧ a>0

Derivation: Algebraic expansion

Basis: If  c (d^2)+9 a (e^2)==0 ∧ a>0, then (((a+c (x^2)))^(1/3))==(a^(1/3)) (((1-((3 e x)/d)))^(1/3)) (((1+((3 e x)/d)))^(1/3))

Rule 1.2.1.2.16.2.1.1: If  c (d^2)+9 a (e^2)==0 ∧ a>0, then

∫(1/((d+e x) (((a+c (x^2)))^(1/3))))dx  ⟶  (a^(1/3)) ∫(1/((d+e x) (((1-((3 e x)/d)))^(1/3)) (((1+((3 e x)/d)))^(1/3))))dx

Program code:

Int[1/((d_+e_.*x_)*(a_+c_.*x_^2)^(1/3)),x_Symbol] :=
  a^(1/3)*Int[1/((d+e*x)*(1-3*e*x/d)^(1/3)*(1+3*e*x/d)^(1/3)),x] /;
FreeQ[{a,c,d,e},x] && EqQ[c*d^2+9*a*e^2,0] && GtQ[a,0]

2:  ∫(1/((d+e x) (((a+c (x^2)))^(1/3))))dx  when  c (d^2)+9 a (e^2)==0 ∧ a≯0

Derivation: Piecewise constant extraction

Basis: (∂_x)((((1+((c (x^2))/a)))^(1/3))/(((a+c (x^2)))^(1/3)))==0

Rule 1.2.1.2.16.2.1.2: If  c (d^2)+9 a (e^2)==0 ∧ a≯0, then

∫(1/((d+e x) (((a+c (x^2)))^(1/3))))dx  ⟶  ((((1+((c (x^2))/a)))^(1/3))/(((a+c (x^2)))^(1/3))) ∫(1/((d+e x) (((1+((c (x^2))/a)))^(1/3))))dx

Program code:

Int[1/((d_+e_.*x_)*(a_+c_.*x_^2)^(1/3)),x_Symbol] :=
  (1+c*x^2/a)^(1/3)/(a+c*x^2)^(1/3)*Int[1/((d+e*x)*(1+c*x^2/a)^(1/3)),x] /;
FreeQ[{a,c,d,e},x] && EqQ[c*d^2+9*a*e^2,0] && Not[GtQ[a,0]]

2:  ∫(1/((d+e x) (((a+b x+c (x^2)))^(1/3))))dx  when  (b^2)-4 a c≠0 ∧ (c^2) (d^2)-b c d e-2 (b^2) (e^2)+9 a c (e^2)==0

Derivation: Piecewise constant extraction

Basis: Let q->(Sqrt[(b^2)-4 a c]), then (∂_x)(((((b+q+2 c x))^(1/3)) (((b-q+2 c x))^(1/3)))/(((a+b x+c (x^2)))^(1/3)))==0

Rule 1.2.1.2.16.2.2: If  (b^2)-4 a c≠0 ∧ (c^2) (d^2)-b c d e-2 (b^2) (e^2)+9 a c (e^2)==0, let q->(Sqrt[(b^2)-4 a c]), then

∫(1/((d+e x) (((a+b x+c (x^2)))^(1/3))))dx  ⟶  (((((b+q+2 c x))^(1/3)) (((b-q+2 c x))^(1/3)))/(((a+b x+c (x^2)))^(1/3))) ∫(1/((d+e x) (((b+q+2 c x))^(1/3)) (((b-q+2 c x))^(1/3))))dx

Program code:

Int[1/((d_.+e_.*x_)*(a_+b_.*x_+c_.*x_^2)^(1/3)),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  (b+q+2*c*x)^(1/3)*(b-q+2*c*x)^(1/3)/(a+b*x+c*x^2)^(1/3)*Int[1/((d+e*x)*(b+q+2*c*x)^(1/3)*(b-q+2*c*x)^(1/3)),x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[b^2-4*a*c,0] && EqQ[c^2*d^2-b*c*d*e-2*b^2*e^2+9*a*c*e^2,0]

17:  ∫(((d+e x))^m)(((a+c (x^2)))^p)dx  when  c (d^2)+a (e^2)≠0 ∧ p∉ℤ ∧ a>0 ∧ c<0

Derivation: Algebraic expansion

Basis: If  a>0, then (((a+c (x^2)))^p)==((((Sqrt[a])+(Sqrt[-c]) x))^p) ((((Sqrt[a])-(Sqrt[-c]) x))^p)

Rule 1.2.1.2.17: If  c (d^2)+a (e^2)≠0 ∧ p∉ℤ ∧ a>0 ∧ c<0, then

∫(((d+e x))^m)(((a+c (x^2)))^p)dx  ⟶  ∫(((d+e x))^m) ((((Sqrt[a])+(Sqrt[-c]) x))^p) ((((Sqrt[a])-(Sqrt[-c]) x))^p)dx

Program code:

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  Int[(d+e*x)^m*(Rt[a,2]+Rt[-c,2]*x)^p*(Rt[a,2]-Rt[-c,2]*x)^p,x] /;
FreeQ[{a,c,d,e,m,p},x] && NeQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && GtQ[a,0] && LtQ[c,0]

19.  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p∉ℤ

1.  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p∉ℤ ∧ m∈(SuperMinus[ℤ])

1:  ∫(((d+e x))^m) (((a+c (x^2)))^p)dx  when c (d^2)+a (e^2)≠0 ∧ p∉ℤ ∧ m∈(SuperMinus[ℤ])

Derivation: Algebraic expansion

Basis: If  m∈ℤ, then (((d+e x))^m)==((((d/((d^2)-(e^2) (x^2)))-((e x)/((d^2)-(e^2) (x^2)))))^(-m))

Note: Resulting integrands are of the form (x^m) (((a+b (x^2)))^p) (((c+d (x^2)))^q) which are integrable in terms of the Appell hypergeometric function .

Rule 1.2.1.2.18: If  c (d^2)+a (e^2)≠0 ∧ p∉ℤ ∧ m∈(SuperMinus[ℤ]), then

∫(((d+e x))^m) (((a+c (x^2)))^p)dx  ⟶  ∫(((a+c (x^2)))^p) ExpandIntegrand[((((d/((d^2)-(e^2) (x^2)))-((e x)/((d^2)-(e^2) (x^2)))))^(-m)),x]dx

Program code:

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(a+c*x^2)^p,(d/(d^2-e^2*x^2)-e*x/(d^2-e^2*x^2))^(-m),x],x] /;
FreeQ[{a,c,d,e,p},x] && NeQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && ILtQ[m,0]

2:  ∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p∉ℤ ∧ m∈(SuperMinus[ℤ])

Derivation: Piecewise constant extraction and integration by substitution

Basis: Let q->(Sqrt[(b^2)-4 a c]), then (∂_x)((((((1/(d+e x))))^(2 p))(((a+b x+c (x^2)))^p))/( (((((e (b-q+2 c x))/(c (d+e x)))))^p) (((((e (b+q+2 c x))/(c (d+e x)))))^p)))==0

Basis: F[x]==-(1/e) Subst[((F[((1-d x)/(e x))])/(x^2)),x,(1/(d+e x))] (∂_x)(1/(d+e x))

Rule 1.2.1.2.19.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p∉ℤ ∧ m∈(SuperMinus[ℤ]), let q->(Sqrt[(b^2)-4 a c]), then

∫(((d+e x))^m) (((a+b x+c (x^2)))^p)dx  ⟶  

((((((1/(d+e x))))^(2 p))(((a+b x+c (x^2)))^p))/( (((((e (b-q+2 c x))/(c (d+e x)))))^p) (((((e (b+q+2 c x))/(c (d+e x)))))^p))) ∫(((((((e (b-q+2 c x))/(c (d+e x)))))^p) (((((e (b+q+2 c x))/(c (d+e x)))))^p))/((((1/(d+e x))))^(m+2 p)))dx  ⟶  

-((((((1/(d+e x))))^(2 p))(((a+b x+c (x^2)))^p))/( e (((((e (b-q+2 c x))/(2 c (d+e x)))))^p) (((((e (b+q+2 c x))/(2 c (d+e x)))))^p))) Subst[∫(x^(-m-2 (p+1))) (((1-(d-((e (b-q))/(2 c))) x))^p) (((1-(d-((e (b+q))/(2 c))) x))^p)dx,x,(1/(d+e x))]

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  -(1/(d+e*x))^(2*p)*(a+b*x+c*x^2)^p/(e*(e*(b-q+2*c*x)/(2*c*(d+e*x)))^p*(e*(b+q+2*c*x)/(2*c*(d+e*x)))^p)*
    Subst[Int[x^(-m-2*(p+1))*Simp[1-(d-e*(b-q)/(2*c))*x,x]^p*Simp[1-(d-e*(b+q)/(2*c))*x,x]^p,x],x,1/(d+e*x)]] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && Not[IntegerQ[p]] && ILtQ[m,0]

2:  ∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p∉ℤ

Derivation: Piecewise constant extraction and integration by substitution

Basis: Let q->(Sqrt[(b^2)-4 a c]), then (∂_x)((((a+b x+c (x^2)))^p)/((((1-((d+e x)/(d-((e (b-q))/(2 c))))))^p) (((1-((d+e x)/(d-((e (b+q))/(2 c))))))^p)))==0

Note: If  c (d^2)-b d e+a (e^2)≠0 and q==(Sqrt[(b^2)-4 a c]), then d-((e (b-q))/(2 c))≠0 and d-((e (b+q))/(2 c))≠0.

Rule 1.2.1.2.19.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ 2 c d-b e≠0 ∧ p∉ℤ, let q->(Sqrt[(b^2)-4 a c]), then

∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx  ⟶  

((((a+b x+c (x^2)))^p)/((((1-((d+e x)/(d-((e (b-q))/(2 c))))))^p) (((1-((d+e x)/(d-((e (b+q))/(2 c))))))^p))) ∫(((d+e x))^m) (((1-((d+e x)/(d-((e (b-q))/(2 c))))))^p) (((1-((d+e x)/(d-((e (b+q))/(2 c))))))^p)dx  ⟶  

((((a+b x+c (x^2)))^p)/(e (((1-((d+e x)/(d-((e (b-q))/(2 c))))))^p) (((1-((d+e x)/(d-((e (b+q))/(2 c))))))^p))) Subst[∫(x^m) (((1-(x/(d-((e (b-q))/(2 c))))))^p) (((1-(x/(d-((e (b+q))/(2 c))))))^p)dx,x,d+e x]

Program code:

Int[(d_.+e_.*x_)^m_*(a_.+b_.*x_+c_.*x_^2)^p_,x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  (a+b*x+c*x^2)^p/(e*(1-(d+e*x)/(d-e*(b-q)/(2*c)))^p*(1-(d+e*x)/(d-e*(b+q)/(2*c)))^p)*
    Subst[Int[x^m*Simp[1-x/(d-e*(b-q)/(2*c)),x]^p*Simp[1-x/(d-e*(b+q)/(2*c)),x]^p,x],x,d+e*x]] /;
FreeQ[{a,b,c,d,e,m,p},x] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && NeQ[2*c*d-b*e,0] && Not[IntegerQ[p]]

Int[(d_+e_.*x_)^m_*(a_+c_.*x_^2)^p_,x_Symbol] :=
  With[{q=Rt[-a*c,2]},
  (a+c*x^2)^p/(e*(1-(d+e*x)/(d+e*q/c))^p*(1-(d+e*x)/(d-e*q/c))^p)*
    Subst[Int[x^m*Simp[1-x/(d+e*q/c),x]^p*Simp[1-x/(d-e*q/c),x]^p,x],x,d+e*x]] /;
FreeQ[{a,c,d,e,m,p},x] && NeQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]]

S:  ∫(((d+e u))^m)(((a+b u+c (u^2)))^p)dx  when  u==f+g x

Derivation: Integration by substitution

Rule 1.2.1.2.S: If  u==f+g x, then

∫(((d+e u))^m)(((a+b u+c (u^2)))^p)dx  ⟶  (1/g)Subst[∫(((d+e x))^m)(((a+b x+c (x^2)))^p)dx,x,u]

Program code:

Int[(d_.+e_.*u_)^m_.*(a_+b_.*u_+c_.*u_^2)^p_.,x_Symbol] :=
  1/Coefficient[u,x,1]*Subst[Int[(d+e*x)^m*(a+b*x+c*x^2)^p,x],x,u] /;
FreeQ[{a,b,c,d,e,m,p},x] && LinearQ[u,x] && NeQ[u,x]

Int[(d_.+e_.*u_)^m_.*(a_+c_.*u_^2)^p_.,x_Symbol] :=
  1/Coefficient[u,x,1]*Subst[Int[(d+e*x)^m*(a+c*x^2)^p,x],x,u] /;
FreeQ[{a,c,d,e,m,p},x] && LinearQ[u,x] && NeQ[u,x]

(* IntQuadraticQ[a,b,c,d,e,m,p,x] returns True iff (d+e*x)^m*(a+b*x+c*x^2)^p is integrable wrt x in terms of non-Appell functions. *)
IntQuadraticQ[a_,b_,c_,d_,e_,m_,p_,x_] :=
  IntegerQ[p] || IGtQ[m,0] || IntegersQ[2*m,2*p] || IntegersQ[m,4*p] || 
  IntegersQ[m,p+1/3] && (EqQ[c^2*d^2-b*c*d*e+b^2*e^2-3*a*c*e^2,0] || EqQ[c^2*d^2-b*c*d*e-2*b^2*e^2+9*a*c*e^2,0])